blob: c9c4a6c27a5441bd723fdd7b82c40981f17ef42c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
SUMMARY = "A liberally licensed VNC server library"
DESCRIPTION = "This is a liberally licensed VNC server library that's intended to be fast and neat."
HOMEPAGE = "https://github.com/any1/neatvnc"
LICENSE = "ISC"
LIC_FILES_CHKSUM = "file://COPYING;md5=94fc374e7174f41e3afe0f027ee59ff7"
SRC_URI = "git://github.com/any1/neatvnc;branch=master;protocol=https"
SRCREV = "46432ce8cade0b54a38d4bb42eb07f96c8ff49fd"
S = "${WORKDIR}/git"
DEPENDS = "libdrm pixman aml zlib"
PACKAGECONFIG ??= ""
PACKAGECONFIG[tls] = "-Dtls=enabled,-Dtls=disabled,gnutls"
PACKAGECONFIG[jpeg] = "-Djpeg=enabled,-Djpeg=disabled,libjpeg-turbo"
PACKAGECONFIG[examples] = "-Dexamples=true,-Dexamples=false,libpng"
PACKAGECONFIG[benchmarks] = "-Dbenchmarks=true,-Dbenchmarks=false,libpng"
PACKAGE_BEFORE_PN += "${PN}-examples"
ALLOW_EMPTY:${PN}-examples = "1"
FILES:${PN}-examples = "${bindir}"
NEATVNC_EXAMPLES = "draw png-server"
inherit meson pkgconfig
do_install:append () {
if ${@bb.utils.contains('PACKAGECONFIG', 'examples', 'true', 'false', d)}; then
install -d ${D}${bindir}
for bin in ${NEATVNC_EXAMPLES}; do
install -m 0755 ${B}/examples/$bin ${D}${bindir}
done
fi
}
BBCLASSEXTEND = "native"
|
