gphoto2: add 2.4.8

libgphoto2: add 2.4.8

1 files changed, 50 insertions, 0 deletions

diff --git a/recipes/gphoto2/libgphoto2_2.4.8.bb b/recipes/gphoto2/libgphoto2_2.4.8.bb
new file mode 100644
index 0000000000..c0f6bc553f
--- /dev/null
+++ b/recipes/gphoto2/libgphoto2_2.4.8.bb
@@ -0,0 +1,50 @@
+DESCRIPTION = "libgphoto2 allows you to access digital cameras"
+SECTION = "libs"
+LICENSE = "GPL"
+DEPENDS = "libtool jpeg virtual/libusb0 libexif"
+
+# The .fdi and .rules files were generated with:
+#  libgphoto2-2.4.7/packaging/generic$ qemu-arm -s 1048576 -r 2.6.24 -L /OE/angstrom-dev/staging/armv5te-angstrom-linux-gnueabi/ .libs/print-camera-list
+# They are release specific, so please regen when adding new releases
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/gphoto/libgphoto2-${PV}.tar.bz2;name=libgphoto2 \
+           file://10-camera-libgphoto2-device.fdi \
+           file://10-camera-libgphoto2.fdi \
+           file://90-libgphoto2.rules \
+"
+
+SRC_URI[libgphoto2.md5sum] = "7753f17dff15702466337aab05209a71"
+SRC_URI[libgphoto2.sha256sum] = "69d7e0723b40e8a0c4fa897b96f6aecb5ae5548c3cce98c48e37b70623d9ffc3"
+
+inherit autotools pkgconfig lib_package
+
+OE_LT_RPATH_ALLOW=":${libdir}:"
+OE_LT_RPATH_ALLOW[export]="1"
+
+EXTRA_OECONF = " --with-drivers=all udevscriptdir=/lib/udev ac_cv_lib_ltdl_lt_dlcaller_register=yes"
+
+do_configure_append() {
+	cd ${S}/libgphoto2_port/
+	autoreconf -Wcross --verbose --install --force ${EXTRA_AUTORECONF} $acpaths
+	cd ${S}
+}
+
+do_install_append() {
+    install -d ${D}${datadir}/hal/fdi/information/20thirdparty
+    install -m 0644 ${WORKDIR}/*.fdi ${D}${datadir}/hal/fdi/information/20thirdparty/
+
+    install -d ${D}${sysconfdir}/udev/rules.d/
+    install -m 0755 ${WORKDIR}/*.rules ${D}${sysconfdir}/udev/rules.d/
+}
+
+PACKAGES =+ "libgphotoport libgphoto2-camlibs"
+FILES_libgphoto2-camlibs = "${libdir}/libgphoto2*/*/*.so*"
+RDEPENDS_${PN} = "libgphoto2-camlibs"
+
+FILES_libgphotoport = "${libdir}/libgphoto2_port.so.*" 
+
+FILES_${PN} += "${libdir}/udev/* ${datadir}/hal"
+FILES_${PN}-dbg += "${libdir}/*/*/.debug"
+
+
+