edje: introduce 1.0.0

* edje_svn is now D_P -1

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

5 files changed, 73 insertions, 69 deletions

diff --git a/recipes/efl1/edje-native_svn.bb b/recipes/efl1/edje-native_svn.bb
deleted file mode 100644
index 420d8c15ae..0000000000
--- a/recipes/efl1/edje-native_svn.bb
+++ /dev/null
@@ -1,11 +0,0 @@
-require edje_${PV}.bb
-inherit native
-PR = "r5"
-
-DEPENDS = "lua5.1-native evas-native ecore-native eet-native embryo-native"
-
-do_configure_prepend() {
-	sed -i 's:EMBRYO_PREFIX"/bin:"${STAGING_BINDIR}:' ${S}/src/bin/edje_cc_out.c
-	sed -i 's: cpp -I: /usr/bin/cpp -I:' ${S}/src/bin/edje_cc_parse.c
-	sed -i 's:\"gcc -I:\"/usr/bin/gcc -I:' ${S}/src/bin/edje_cc_parse.c
-}
diff --git a/recipes/efl1/edje-sdk_svn.bb b/recipes/efl1/edje-sdk_svn.bb
deleted file mode 100644
index e91652e16d..0000000000
--- a/recipes/efl1/edje-sdk_svn.bb
+++ /dev/null
@@ -1,9 +0,0 @@
-require edje_svn.bb
-
-inherit sdk
-PR = "r4"
-
-SRCNAME = "${@bb.data.getVar('PN', d, 1).replace('-sdk', '')}"
-DEPENDS = "evas-native ecore-native eet-native embryo-native"
-S = "${WORKDIR}/edje"
-
diff --git a/recipes/efl1/edje.inc b/recipes/efl1/edje.inc
new file mode 100644
index 0000000000..c69314f43f
--- /dev/null
+++ b/recipes/efl1/edje.inc
@@ -0,0 +1,55 @@
+DESCRIPTION = "Edje is the Enlightenment graphical design & layout library"
+DEPENDS = "lua5.1 eet evas ecore embryo edje-native"
+DEPENDS_virtclass-native = "lua5.1-native evas-native ecore-native eet-native embryo-native"
+DEPENDS_virtclass-nativesdk = "evas-native ecore-native eet-native embryo-native"
+LICENSE = "MIT BSD"
+
+inherit efl
+
+BBCLASSEXTEND = "native nativesdk"
+INC_PR = "r0"
+
+do_configure_prepend_virtclass-native() {
+	sed -i 's:EMBRYO_PREFIX"/bin:"${STAGING_BINDIR}:' ${S}/src/bin/edje_cc_out.c
+	sed -i 's: cpp -I: /usr/bin/cpp -I:' ${S}/src/bin/edje_cc_parse.c
+	sed -i 's:\"gcc -I:\"/usr/bin/gcc -I:' ${S}/src/bin/edje_cc_parse.c
+}
+# The new lua stuff is a bit broken...
+do_configure_append() {
+	for i in $(find "${S}" -name "Makefile") ; do
+		sed -i -e 's:-L/usr/local/lib::g'  $i
+	done
+}
+
+do_compile_append() {
+	sed -i -e s:local/::g -e 's:-L${STAGING_LIBDIR}::g' ${S}/edje.pc
+}
+
+# gain some extra performance at the expense of RAM - generally i'd say bad
+# and a possible source of bugs
+#EXTRA_OECONF = "--enable-edje-program-cache"
+
+# Since r44323 edje has a fixed-point mode
+require edje-fpu.inc
+EXTRA_OECONF += "${@get_edje_fpu_setting(bb, d)}"
+
+PACKAGES =+ "${PN}-utils"
+RDEPENDS_${PN}-utils = "cpp cpp-symlinks embryo-tests"
+
+RRECOMMENDS_${PN}-utils = "\
+  evas-saver-png \
+  evas-saver-jpeg \
+  evas-saver-eet \
+"
+
+DEBIAN_NOAUTONAME_${PN}-utils = "1"
+# Some upgrade path tweaking
+AUTO_LIBNAME_PKGS = ""
+
+RREPLACES_${PN} = "libedje-ver-pre-svn-00-0 libedje-ver-pre-svn-01-0"
+
+FILES_${PN}-utils = "\
+  ${bindir}/edje_* \
+  ${bindir}/inkscape2edc \
+  ${datadir}/edje/include/edje.inc \
+"
diff --git a/recipes/efl1/edje_1.0.0.bb b/recipes/efl1/edje_1.0.0.bb
new file mode 100644
index 0000000000..d6b2f3e628
--- /dev/null
+++ b/recipes/efl1/edje_1.0.0.bb
@@ -0,0 +1,10 @@
+require edje.inc
+
+PR = "${INC_PR}.0"
+
+SRC_URI = "\
+  ${E_MIRROR}/${SRCNAME}-${PV}.tar.gz \
+"
+
+SRC_URI[md5sum] = "14c33c2b9d1bd36d8507d55597c77991"
+SRC_URI[sha256sum] = "6dace9249cccb488170e1a17ce9f1a00d160281d4a6512b482f6dd27327e6235"
diff --git a/recipes/efl1/edje_svn.bb b/recipes/efl1/edje_svn.bb
index 1018d048bc..65d723d33a 100644
--- a/recipes/efl1/edje_svn.bb
+++ b/recipes/efl1/edje_svn.bb
@@ -1,52 +1,11 @@
-DESCRIPTION = "Edje is the Enlightenment graphical design & layout library"
-DEPENDS = "lua5.1 eet evas ecore embryo edje-native"
-LICENSE = "MIT BSD"
-PV = "0.9.92.060+svnr${SRCPV}"
-PR = "r7"
-SRCREV = "${EFL_SRCREV}"
-
-inherit efl
-
-SRC_URI = "${E_SVN}/trunk;module=${SRCNAME};proto=http;scmdata=keep"
-S = "${WORKDIR}/${SRCNAME}"
-
-# The new lua stuff is a bit broken...
-do_configure_append() {
-	for i in $(find "${S}" -name "Makefile") ; do
-		sed -i -e 's:-L/usr/local/lib::g'  $i
-	done
-}
-
-do_compile_append() {
-	sed -i -e s:local/::g -e 's:-L${STAGING_LIBDIR}::g' ${S}/edje.pc
-}
-
-# gain some extra performance at the expense of RAM - generally i'd say bad
-# and a possible source of bugs
-#EXTRA_OECONF = "--enable-edje-program-cache"
-
-# Since r44323 edje has a fixed-point mode
-require edje-fpu.inc
-EXTRA_OECONF += "${@get_edje_fpu_setting(bb, d)}"
+require edje.inc
 
+SRCREV = "${EFL_SRCREV}"
+PV = "1.0.999+svnr${SRCPV}"
+PR = "${INC_PR}.0"
+DEFAULT_PREFERENCE = "-1"
 
-PACKAGES =+ "${PN}-utils"
-RDEPENDS_${PN}-utils = "cpp cpp-symlinks embryo-tests"
-
-RRECOMMENDS_${PN}-utils = "\
-  evas-saver-png \
-  evas-saver-jpeg \
-  evas-saver-eet \
-"
-
-DEBIAN_NOAUTONAME_${PN}-utils = "1"
-# Some upgrade path tweaking
-AUTO_LIBNAME_PKGS = ""
-
-RREPLACES_${PN} = "libedje-ver-pre-svn-00-0 libedje-ver-pre-svn-01-0"
-
-FILES_${PN}-utils = "\
-  ${bindir}/edje_* \
-  ${bindir}/inkscape2edc \
-  ${datadir}/edje/include/edje.inc \
+SRC_URI = "\
+  ${E_SVN}/trunk;module=${SRCNAME};proto=http;scmdata=keep \
 "
+S = "${WORKDIR}/${SRCNAME}"