blob: 48c545660d716df29a260f1591b23f8f974e6a32 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
SUMMARY = "Tools for managing AUFS mounts"
SECTION = "base"
HOMEPAGE = "http://aufs.sourceforge.net/"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=892f569a555ba9c07a568a7c0c4fa63a"
DEPENDS = "aufs-util-native"
DEPENDS_class-native = ""
SRCREV = "f29056fe396d56fc2a06a96312feabaebbe14c59"
SRC_URI = "git://git.code.sf.net/p/aufs/aufs-util;protocol=git;branch=aufs3.9 \
file://aufs-util-don-t-strip-executables.patch \
file://aufs-util-add-tool-concept-to-Makefile-for-cross-com.patch \
file://aufs_type.h \
"
PV = "3.9+git${SRCPV}"
S = "${WORKDIR}/git"
do_configure_append () {
install -d ${S}/include/linux/
cp ${WORKDIR}/aufs_type.h ${S}/include/linux/
}
do_configure_append_class-target () {
for i in ver c2sh c2tmac; do
cp ${STAGING_BINDIR_NATIVE}/aufs-util-${PV}/$i ./
done
}
do_compile () {
oe_runmake CPPFLAGS="-I${S}/include -I${S}/libau"
}
do_compile_class-native () {
oe_runmake tools CPPFLAGS="-I${S}/include -I${S}/libau"
}
do_install () {
oe_runmake 'DESTDIR=${D}' install_sbin install_ubin install_etc
}
do_install_class-native () {
install -d ${D}${bindir}/aufs-util-${PV}
for i in ver c2sh c2tmac; do
install -m 755 $i ${D}${bindir}/aufs-util-${PV}/$i
done
}
RRECOMMENDS_${PN} += "kernel-module-aufs"
BBCLASSEXTEND = "native"
|
