From 709c4d66e0b107ca606941b988bad717c0b45d9b Mon Sep 17 00:00:00 2001
From: Denys Dmytriyenko <denis@denix.org>
Date: Tue, 17 Mar 2009 14:32:59 -0400
Subject: rename packages/ to recipes/ per earlier agreement

See links below for more details:
http://thread.gmane.org/gmane.comp.handhelds.openembedded/21326
http://thread.gmane.org/gmane.comp.handhelds.openembedded/21816

Signed-off-by: Denys Dmytriyenko <denis@denix.org>
Acked-by: Mike Westerhof <mwester@dls.net>
Acked-by: Philip Balister <philip@balister.org>
Acked-by: Khem Raj <raj.khem@gmail.com>
Acked-by: Marcin Juszkiewicz <hrw@openembedded.org>
Acked-by: Koen Kooi <koen@openembedded.org>
Acked-by: Frans Meulenbroeks <fransmeulenbroeks@gmail.com>
---
 recipes/netpbm/netpbm_10.28.bb | 90 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 90 insertions(+)
 create mode 100644 recipes/netpbm/netpbm_10.28.bb

(limited to 'recipes/netpbm/netpbm_10.28.bb')

diff --git a/recipes/netpbm/netpbm_10.28.bb b/recipes/netpbm/netpbm_10.28.bb
new file mode 100644
index 0000000000..ff90310e1b
--- /dev/null
+++ b/recipes/netpbm/netpbm_10.28.bb
@@ -0,0 +1,90 @@
+DESCRIPTION = "Netpbm is a toolkit for manipulation of graphic images, including\
+conversion of images between a variety of different formats.  There\
+are over 220 separate tools in the package including converters for\
+about 100 graphics formats."
+HOMEPAGE = "http://netpbm.sourceforge.net"
+SECTION = "console/utils"
+LICENSE = "GPL MIT Artistic"
+# NOTE: individual command line utilities are covered by different
+# licenses.  The compiled and linked command line utilties are
+# subject to the licenses of the libraries they use too - including
+# libpng libz, IJG, and libtiff licenses
+DEPENDS = "jpeg zlib libpng tiff install-native flex-native"
+RDEPENDS = "perl\
+	perl-module-cwd\
+	perl-module-english\
+	perl-module-fcntl\
+	perl-module-file-basename\
+	perl-module-file-spec\
+	perl-module-getopt-long\
+	perl-module-strict\
+	"
+
+# these should not be required, they are here because the perl
+# module dependencies are currently incorrect:
+RDEPENDS += "perl-module-exporter-heavy"
+RDEPENDS += "perl-module-file-spec-unix"
+
+PR = "r5"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/netpbm/netpbm-${PV}.tgz \
+	   file://ppmtojpeg.patch;patch=42 \
+	   file://Makefile.config \
+	   file://oeendiangen"
+
+PARALLEL_MAKE = ""
+
+EXTRA_OEMAKE = "ENDIANGEN=${S}/buildtools/oeendiangen TARGET_LD=${LD}"
+
+do_configure() {
+	install -c -m 644 ../Makefile.config .
+	# The following stops the host endiangen program being run and uses
+	# the target endian.h header instead.
+	install -c -m 755 ../oeendiangen buildtools
+}
+
+do_compile() {
+	# need all to get the static library too
+	oe_runmake all default
+}
+
+do_install() {
+	# netpbm makes its own installation package, which must then be
+	# installed to form the dummy installation for ipkg
+	rm -rf ${WORKDIR}/netpbm-package
+	oe_runmake package pkgdir=${WORKDIR}/netpbm-package
+	# now install the stuff from the package into ${D}
+	for d in ${WORKDIR}/netpbm-package/*
+	do
+		# following will cause an error if used
+		case "$d" in
+		*/README)	;;
+		*/VERSION)	;;
+		*/pkginfo)	;;
+		*/bin)		install -d ${D}${bindir}
+				cp -pPR "$d"/* ${D}${bindir}
+				rm ${D}${bindir}/doc.url;;
+		*/include)	install -d ${D}${includedir}
+				cp -pPR "$d"/* ${D}${includedir};;
+		*/link|*/lib)	install -d ${D}${libdir}
+				cp -pPR "$d"/* ${D}${libdir};;
+		*/man)		install -d ${D}${mandir}
+				cp -pPR "$d"/* ${D}${mandir};;
+		*/misc)		install -d ${D}${datadir}/netpbm
+				cp -pPR "$d"/* ${D}${datadir}/netpbm;;
+		*/config_template)
+				install -d ${D}${bindir}
+				sed "/^@/d
+					s!@VERSION@!$(<'${WORKDIR}/netpbm-package/VERSION')!
+					s!@DATADIR@!${datadir}/netpbm!
+					s!@LIBDIR@!${libdir}!
+					s!@LINKDIR@!${libdir}!
+					s!@INCLUDEDIR@!${includedir}!
+					s!@BINDIR@!${bindir}!
+					" "$d" >${D}${bindir}/netpbm-config
+				chmod 755 ${D}${bindir}/netpbm-config;;
+		*)		echo "netpbm-package/$d: unknown item" >&2
+				exit 1;;
+		esac
+	done
+}
-- 
cgit 1.2.3-korg