From 709c4d66e0b107ca606941b988bad717c0b45d9b Mon Sep 17 00:00:00 2001
From: Denys Dmytriyenko <denis@denix.org>
Date: Tue, 17 Mar 2009 14:32:59 -0400
Subject: rename packages/ to recipes/ per earlier agreement

See links below for more details:
http://thread.gmane.org/gmane.comp.handhelds.openembedded/21326
http://thread.gmane.org/gmane.comp.handhelds.openembedded/21816

Signed-off-by: Denys Dmytriyenko <denis@denix.org>
Acked-by: Mike Westerhof <mwester@dls.net>
Acked-by: Philip Balister <philip@balister.org>
Acked-by: Khem Raj <raj.khem@gmail.com>
Acked-by: Marcin Juszkiewicz <hrw@openembedded.org>
Acked-by: Koen Kooi <koen@openembedded.org>
Acked-by: Frans Meulenbroeks <fransmeulenbroeks@gmail.com>
---
 recipes/exmap-console/exmap-console.inc      | 61 ++++++++++++++++++++++++++++
 recipes/exmap-console/exmap-console_0.4.1.bb |  3 ++
 recipes/exmap-console/exmap-console_svn.bb   | 11 +++++
 3 files changed, 75 insertions(+)
 create mode 100644 recipes/exmap-console/exmap-console.inc
 create mode 100644 recipes/exmap-console/exmap-console_0.4.1.bb
 create mode 100644 recipes/exmap-console/exmap-console_svn.bb

(limited to 'recipes/exmap-console')

diff --git a/recipes/exmap-console/exmap-console.inc b/recipes/exmap-console/exmap-console.inc
new file mode 100644
index 0000000000..6744aed49f
--- /dev/null
+++ b/recipes/exmap-console/exmap-console.inc
@@ -0,0 +1,61 @@
+DESCRIPTION = "Console based version of exmap, a memory usage analysis tool"
+HOMEPAGE = "http://projects.o-hand.com/exmap-console"
+SECTION = "devel"
+LICENSE = "GPL"
+DEPENDS = "virtual/kernel readline"
+
+SRC_URI = "http://projects.o-hand.com/sources/exmap-console/exmap-console-${PV}.tgz"
+
+TEMPPACKAGE_ARCH := "${PACKAGE_ARCH}"
+
+inherit module-base
+inherit autotools
+
+MYPV := "${PV}"
+PACKAGE_ARCH = "${TEMPPACKAGE_ARCH}"
+
+PACKAGES =+ "exmap-server kernel-module-exmap"
+
+FILES_exmap-console = "${bindir}/exmap ${bindir}/exmapd"
+RDEPENDS_exmap-console += "kernel-module-exmap"
+
+FILES_exmap-server = "${bindir}/exmapserver"
+RDEPENDS_exmap-server += "kernel-module-exmap"
+
+FILES_kernel-module-exmap = "${base_libdir}"
+PACKAGE_ARCH_kernel-module-exmap = "${MACHINE_ARCH}"
+PV_kernel-module-exmap = "${MYPV}-${KERNEL_VERSION}"
+RDEPENDS_kernel-module-exmap += "update-modules kernel-image-${KERNEL_VERSION}"
+
+S = "${WORKDIR}/exmap-console-${PV}"
+
+export MODULE_PATH="${D}${base_libdir}/modules/${KERNEL_VERSION}"
+
+do_compile() {
+	cd ${S}/src
+	make
+
+	cd ${S}/kernel
+	unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
+	oe_runmake KERNEL_PATH=${STAGING_KERNEL_DIR}   \
+		   KERNEL_SRC=${STAGING_KERNEL_DIR}    \
+		   KERNEL_VERSION=${KERNEL_VERSION}    \
+		   CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
+		   ${MAKE_TARGETS}
+}
+
+do_install() {
+	oe_runmake 'DESTDIR=${D}' 'DEPMOD=/bin/true' install
+}
+
+pkg_postinst_append_kernel-module-exmap () {
+	if [ -n "$D" ]; then
+		exit 1
+	fi
+	depmod -a
+	update-modules || true
+}
+
+pkg_postrm_append_kernel-module-exmap () {
+	update-modules || true
+}
diff --git a/recipes/exmap-console/exmap-console_0.4.1.bb b/recipes/exmap-console/exmap-console_0.4.1.bb
new file mode 100644
index 0000000000..e1ddf7de1f
--- /dev/null
+++ b/recipes/exmap-console/exmap-console_0.4.1.bb
@@ -0,0 +1,3 @@
+require exmap-console.inc
+
+PR = "r5"
diff --git a/recipes/exmap-console/exmap-console_svn.bb b/recipes/exmap-console/exmap-console_svn.bb
new file mode 100644
index 0000000000..6e86214b1c
--- /dev/null
+++ b/recipes/exmap-console/exmap-console_svn.bb
@@ -0,0 +1,11 @@
+require exmap-console.inc
+
+PV = "0.4+svnr${SRCREV}"
+PR = "r1"
+
+SRC_URI = "svn://svn.o-hand.com/repos/misc/trunk;module=exmap-console;proto=http"
+
+S = "${WORKDIR}/exmap-console"
+
+MYPV := "${PV}"
+PV_kernel-module-exmap = "${MYPV}-${KERNEL_VERSION}"
-- 
cgit 1.2.3-korg