From 2259a81628ac8bafb19e2b9ba9acca1c0dad341d Mon Sep 17 00:00:00 2001
From: Chris Larson <clarson@mvista.com>
Date: Wed, 26 Aug 2009 14:44:04 -0700
Subject: srctree, clean: cleanup & split out do_clean bits into clean.bbclass.

Signed-off-by: Chris Larson <clarson@mvista.com>
---
 classes/clean.bbclass | 53 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 classes/clean.bbclass

(limited to 'classes/clean.bbclass')

diff --git a/classes/clean.bbclass b/classes/clean.bbclass
new file mode 100644
index 0000000000..65c1ab5d76
--- /dev/null
+++ b/classes/clean.bbclass
@@ -0,0 +1,53 @@
+def clean_builddir(d):
+	from shutil import rmtree
+
+	builddir = d.getVar("B", True)
+	srcdir = d.getVar("S", True)
+	if builddir != srcdir:
+		rmtree(builddir, ignore_errors=True)
+
+def clean_stamps(d):
+	from glob import glob
+	from bb import note
+	from bb.data import expand
+	from os import unlink
+
+	note("Removing stamps")
+	for stamp in glob(expand('${STAMP}.*', d)):
+		try:
+			unlink(stamp)
+		except OSError:
+			pass
+
+def clean_workdir(d):
+	from shutil import rmtree
+	from bb import note
+
+	workdir = d.getVar("WORKDIR", 1)
+	note("Removing %s" % workdir)
+	rmtree(workdir, ignore_errors=True)
+
+def clean_git(d):
+	from subprocess import call
+
+	call(["git", "clean", "-d", "-f", "-X"], cwd=d.getVar("S", True))
+
+def clean_make(d):
+	import bb
+
+	bb.note("Running make clean")
+	try:
+		bb.build.exec_func("__do_clean_make", d)
+	except bb.build.FuncFailed:
+		pass
+
+__do_clean_make () {
+	oe_runmake clean
+}
+
+python do_clean () {
+	clean_stamps(d)
+	clean_workdir(d)
+	clean_builddir(d)
+	clean_make(d)
+}
-- 
cgit 1.2.3-korg