opencv,opencv-samples: add 2.2

Signed-off-by: Koen Kooi <koen@openembedded.org>

2 files changed, 98 insertions, 0 deletions

diff --git a/recipes/opencv/opencv-samples_2.2.bb b/recipes/opencv/opencv-samples_2.2.bb
new file mode 100644
index 0000000000..b97cd11c6b
--- /dev/null
+++ b/recipes/opencv/opencv-samples_2.2.bb
@@ -0,0 +1,39 @@
+DESCRIPTION = "Opencv : The Open Computer Vision Library"
+HOMEPAGE = "http://sourceforge.net/projects/opencvlibrary"
+SECTION = "libs"
+PRIORITY = "optional"
+LICENSE = "GPLv2"
+
+DEPENDS = "opencv"
+
+SRC_URI = "svn://code.ros.org/svn/opencv/branches/2.2;module=opencv;proto=https \
+"
+
+SRCREV = "4441"
+PV = "2.2.0+svnr${SRCPV}"
+
+S = "${WORKDIR}/opencv"
+
+do_install() {
+    cd samples/c
+	install -d ${D}/${bindir}
+	install -d ${D}/${datadir}/opencv/samples
+
+	cp * ${D}/${datadir}/opencv/samples || true
+
+    for i in *.c; do
+        echo "compiling $i"
+        ${CXX} ${CFLAGS} ${LDFLAGS} -ggdb `pkg-config --cflags opencv` -o `basename $i .c` $i `pkg-config --libs opencv` || true
+		install -m 0755 `basename $i .c` ${D}/${bindir} || true
+		rm ${D}/${datadir}/opencv/samples/`basename $i .c` || true
+	done
+    for i in *.cpp; do
+        echo "compiling $i"
+        ${CXX} ${CFLAGS} ${LDFLAGS} -ggdb `pkg-config --cflags opencv` -o `basename $i .cpp` $i `pkg-config --libs opencv` || true
+		install -m 0755 `basename $i .cpp` ${D}/${bindir} || true
+		rm ${D}/${datadir}/opencv/samples/`basename $i .cpp` || true
+	done
+}
+
+FILES_${PN}-dev += "${datadir}/opencv/samples/*.c* ${datadir}/opencv/samples/*.vcp* ${datadir}/opencv/samples/build*" 
+FILES_${PN} += "${bindir} ${datadir}/opencv"
diff --git a/recipes/opencv/opencv_2.2.bb b/recipes/opencv/opencv_2.2.bb
new file mode 100644
index 0000000000..c962df91e6
--- /dev/null
+++ b/recipes/opencv/opencv_2.2.bb
@@ -0,0 +1,59 @@
+DESCRIPTION = "Opencv : The Open Computer Vision Library"
+HOMEPAGE = "http://sourceforge.net/projects/opencvlibrary"
+SECTION = "libs"
+PRIORITY = "optional"
+LICENSE = "GPLv2"
+
+ARM_INSTRUCTION_SET = "arm"
+
+DEPENDS = "python-numpy ffmpeg gtk+ libtool swig swig-native python jpeg bzip2 zlib libpng tiff glib-2.0"
+
+SRC_URI = "svn://code.ros.org/svn/opencv/branches/2.2;module=opencv;proto=https \
+"
+
+PARALLEL_MAKE = ""
+
+SRCREV = "4462"
+PV = "2.2.0+svnr${SRCPV}"
+PR = "r0"
+
+S = "${WORKDIR}/opencv"
+
+inherit distutils-base pkgconfig cmake
+
+EXTRA_OECMAKE = "-DBUILD_TESTS=0"
+
+export BUILD_SYS
+export HOST_SYS
+export PYTHON_CSPEC="-I${STAGING_INCDIR}/${PYTHON_DIR}"
+export PYTHON=${STAGING_BINDIR_NATIVE}/python
+
+TARGET_CC_ARCH += "-I${S}/include "
+
+PACKAGES += "${PN}-apps python-opencv"
+
+python populate_packages_prepend () {
+	cv_libdir = bb.data.expand('${libdir}', d)
+	cv_libdir_dbg = bb.data.expand('${libdir}/.debug', d)
+	do_split_packages(d, cv_libdir, '^lib(.*)\.so$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev', allow_links=True)
+	do_split_packages(d, cv_libdir, '^lib(.*)\.la$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev')
+	do_split_packages(d, cv_libdir, '^lib(.*)\.a$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev')
+	do_split_packages(d, cv_libdir, '^lib(.*)\.so\.*', 'lib%s', 'OpenCV %s library', extra_depends='', allow_links=True)
+}
+
+FILES_${PN} = ""
+FILES_${PN}-apps = "${bindir}/* ${datadir}/opencv/"
+FILES_${PN}-dbg += "${libdir}/.debug"
+FILES_${PN}-dev = "${includedir} ${libdir}/pkgconfig"
+
+ALLOW_EMPTY_${PN} = "1"
+
+INSANE_SKIP_python-opencv = True
+DESCRIPTION_python-opencv = "Python bindings to opencv"
+FILES_python-opencv = "${PYTHON_SITEPACKAGES_DIR}/*"
+RDEPENDS_python-opencv = "python-core python-numpy"
+
+do_install_append() {
+	cp ${S}/include/opencv/*.h ${D}${includedir}/opencv/
+	sed -i '/blobtrack/d' ${D}${includedir}/opencv/cvaux.h
+}