From 29d6678fd546377459ef75cf54abeef5b969b5cf Mon Sep 17 00:00:00 2001
From: Richard Purdie <rpurdie@linux.intel.com>
Date: Fri, 27 Aug 2010 15:14:24 +0100
Subject: Major layout change to the packages directory

Having one monolithic packages directory makes it hard to find things
and is generally overwhelming. This commit splits it into several
logical sections roughly based on function, recipes.txt gives more
information about the classifications used.

The opportunity is also used to switch from "packages" to "recipes"
as used in OpenEmbedded as the term "packages" can be confusing to
people and has many different meanings.

Not all recipes have been classified yet, this is just a first pass
at separating things out. Some packages are moved to meta-extras as
they're no longer actively used or maintained.

Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>
---
 .../net-tools/net-tools_1.60-23.bb                 | 77 ++++++++++++++++++++++
 1 file changed, 77 insertions(+)
 create mode 100644 meta/recipes-extended/net-tools/net-tools_1.60-23.bb

(limited to 'meta/recipes-extended/net-tools/net-tools_1.60-23.bb')

diff --git a/meta/recipes-extended/net-tools/net-tools_1.60-23.bb b/meta/recipes-extended/net-tools/net-tools_1.60-23.bb
new file mode 100644
index 0000000000..031169c067
--- /dev/null
+++ b/meta/recipes-extended/net-tools/net-tools_1.60-23.bb
@@ -0,0 +1,77 @@
+SUMMARY="A collection of programs that form the base set of the NET-3 networking distribution for the Linux operating system"
+HOMEPAGE = "http://net-tools.berlios.de/"
+BUGTRACKER = "http://bugs.debian.org/net-tools"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=8ca43cbc842c2336e835926c2166c28b \
+                    file://ifconfig.c;startline=11;endline=15;md5=da4c7bb79a5d0798faa99ef869721f4a"
+PR = "r0"
+
+SRC_URI = "ftp://ftp.debian.org/debian/pool/main/n/net-tools/net-tools_1.60.orig.tar.gz \
+           ftp://ftp.debian.org/debian/pool/main/n/net-tools/${PN}_${PV}.diff.gz;apply=no \
+           file://net-tools-config.h \
+           file://net-tools-config.make" 
+
+S = "${WORKDIR}/net-tools-1.60"
+
+inherit gettext
+
+# The Makefile is lame, no parallel build
+PARALLEL_MAKE = ""
+
+# Unlike other Debian packages, net-tools *.diff.gz contains another series of
+# patches maintained by quilt. So manually apply them before applying other local
+# patches. Also remove all temp files before leaving, because do_patch() will pop 
+# up all previously applied patches in the start
+nettools_do_patch() {
+	cd ${S}
+	patch -p1 < ${WORKDIR}/${PN}_${PV}.diff
+	QUILT_PATCHES=${S}/debian/patches quilt push -a
+	rm -rf ${S}/patches ${S}/.pc
+}
+
+# We invoke base do_patch at end, to incorporate any local patch
+python do_patch() {
+	bb.build.exec_func('nettools_do_patch', d)
+	bb.build.exec_func('patch_do_patch', d)
+}
+
+do_configure() {
+	# net-tools has its own config mechanism requiring "make config"
+	# we pre-generate desired options and copy to source directory instead
+	cp ${WORKDIR}/net-tools-config.h    ${S}/config.h
+	cp ${WORKDIR}/net-tools-config.make ${S}/config.make
+}
+
+do_compile() {
+	# net-tools use COPTS/LOPTS to allow adding custom options
+	export COPTS="$CFLAGS"
+	export LOPTS="$LDFLAGS"
+	unset CFLAGS
+	unset LDFLAGS
+
+	oe_runmake
+}
+
+do_install() {
+	oe_runmake 'BASEDIR=${D}' install
+
+	for app in ${D}/${base_sbindir}/* ${D}/${base_bindir}/*; do
+		mv $app $app.${PN}
+	done
+}
+
+pkg_postinst_${PN} () {
+	for app in arp ifconfig ipmaddr iptunnel mii-tool nameif plipconfig rarp route slattach ; do
+		update-alternatives --install ${base_sbindir}/$app $app $app.${PN} 100
+	done
+
+	for app in dnsdomainname domainname hostname netstat nisdomainname ypdomainname ; do
+		update-alternatives --install ${base_bindir}/$app $app $app.${PN} 100
+	done
+}
+
+pkg_prerm_${PN} () {
+	for app in arp ifconfig ipmaddr iptunnel mii-tool nameif plipconfig rarp route slattach dnsdomainname domainname hostname netstat nisdomainname ypdomainname ; do
+		update-alternatives --remove $app $app.${PN}
+	done
+}
-- 
cgit 1.2.3-korg