summaryrefslogtreecommitdiffstats
path: root/meta/recipes-graphics
diff options
context:
space:
mode:
authorRoss Burton <ross.burton@intel.com>2013-09-02 17:13:32 +0100
committerRichard Purdie <richard.purdie@linuxfoundation.org>2013-09-06 22:54:42 +0100
commita8835cc014d761bf18a420b48c7c61cdfeded552 (patch)
tree646514eb473c3f61a12779f22009498063a55ca4 /meta/recipes-graphics
parent2b148b9e73f05af33ed1437358fa5322cf364651 (diff)
downloadopenembedded-core-a8835cc014d761bf18a420b48c7c61cdfeded552.tar.gz
openembedded-core-a8835cc014d761bf18a420b48c7c61cdfeded552.tar.bz2
openembedded-core-a8835cc014d761bf18a420b48c7c61cdfeded552.zip
eglinfo: add recipes for x11 and fb backends
eglinfo is a small utility for printing out information about EGL as well as about its client APIs, OpenGL / OpenGLES 1.x / OpenGLES 2.x / OpenVG. Recipe originally by Carlos Rafael Giani <dv@pseudoterminal.org>. Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-graphics')
-rw-r--r--meta/recipes-graphics/eglinfo/eglinfo-fb_1.0.bb11
-rw-r--r--meta/recipes-graphics/eglinfo/eglinfo-x11_1.0.bb8
-rw-r--r--meta/recipes-graphics/eglinfo/eglinfo.inc32
3 files changed, 51 insertions, 0 deletions
diff --git a/meta/recipes-graphics/eglinfo/eglinfo-fb_1.0.bb b/meta/recipes-graphics/eglinfo/eglinfo-fb_1.0.bb
new file mode 100644
index 0000000000..65b265fcb7
--- /dev/null
+++ b/meta/recipes-graphics/eglinfo/eglinfo-fb_1.0.bb
@@ -0,0 +1,11 @@
+EGLINFO_PLATFORM ?= "fb"
+EGLINFO_BINARY_NAME ?= "eglinfo-fb"
+
+# .bbappend files in BSP meta layers can add EGLINFO_DEVICE
+# values if necessary. eglinfo.inc contains default values for
+# the currently supported devices.
+# Consult the eglinfo README.md for details
+
+include eglinfo.inc
+
+SUMMARY += "(Framebuffer version)"
diff --git a/meta/recipes-graphics/eglinfo/eglinfo-x11_1.0.bb b/meta/recipes-graphics/eglinfo/eglinfo-x11_1.0.bb
new file mode 100644
index 0000000000..18fc8938d6
--- /dev/null
+++ b/meta/recipes-graphics/eglinfo/eglinfo-x11_1.0.bb
@@ -0,0 +1,8 @@
+EGLINFO_PLATFORM ?= "x11"
+EGLINFO_BINARY_NAME ?= "eglinfo-x11"
+
+include eglinfo.inc
+
+DEPENDS += "virtual/libx11"
+
+SUMMARY += "(X11 version)"
diff --git a/meta/recipes-graphics/eglinfo/eglinfo.inc b/meta/recipes-graphics/eglinfo/eglinfo.inc
new file mode 100644
index 0000000000..d53d0ff21e
--- /dev/null
+++ b/meta/recipes-graphics/eglinfo/eglinfo.inc
@@ -0,0 +1,32 @@
+SUMMARY = "Utility for printing information EGL and its client APIs (OpenGL, OpenGL ES, OpenVG)"
+SECTION = "graphics"
+LICENSE = "Zlib"
+HOMEPAGE = "https://github.com/dv1/eglinfo"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=8d4f33bc3add976f7dfae85dab66f03c"
+
+DEPENDS = "virtual/egl"
+
+SRC_URI = "git://github.com/dv1/eglinfo.git;branch=master"
+SRCREV = "4a49ff59545d9b6a8222badab64115f89d3a6774"
+
+S = "${WORKDIR}/git"
+
+inherit waf
+
+# BSP layers should add .bbappend files for the -x11 and -fb .bb recipes,
+# which append the respective EGL/OpenGLES/OpenVG libraries to DEPENDS
+# not doing that here, since some platforms might not have OpenGL ES or OpenVG support
+# (in that case, the eglinfo build scripts automatically disable the relevant code paths)
+
+EGLINFO_DEVICE ?= "generic"
+EGLINFO_DEVICE_raspberrypi ?= "raspberrypi"
+EGLINFO_DEVICE_beagleboard ?= "beagleboard"
+EGLINFO_DEVICE_mx6 ?= "imx6"
+
+EXTRA_OECONF = "--platform=${EGLINFO_PLATFORM} \
+ --device=${EGLINFO_DEVICE} \
+ --sysroot ${STAGING_DIR_TARGET}"
+
+do_install_append() {
+ mv ${D}/${bindir}/eglinfo ${D}/${bindir}/${EGLINFO_BINARY_NAME}
+}