blob: 2bb9e6f32d88b8f3606019124d7e594d1faab365 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
LICENSE = "GPL-3.0-or-later"
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
require diffutils.inc
SRC_URI = "${GNU_MIRROR}/diffutils/diffutils-${PV}.tar.xz \
file://run-ptest \
file://0001-Skip-strip-trailing-cr-test-case.patch \
"
SRC_URI[sha256sum] = "d80d3be90a201868de83d78dad3413ad88160cc53bcc36eb9eaf7c20dbf023f1"
EXTRA_OECONF += "ac_cv_path_PR_PROGRAM=${bindir}/pr --without-libsigsegv-prefix"
# latest gnulib is no longer able to handle this - I dare not try to fix that maze of abstractions and generators
CFLAGS:mingw32 = " -DSA_RESTART=0"
# Fix "Argument list too long" error when len(TMPDIR) = 410
acpaths = "-I ./m4"
EXTRA_OEMAKE:append:mingw32 = " LIBS='-lbcrypt'"
inherit ptest
RDEPENDS:${PN}-ptest += "make perl"
do_install_ptest() {
t=${D}${PTEST_PATH}
install -D ${S}/build-aux/test-driver $t/build-aux/test-driver
cp -r ${S}/tests $t/
install ${B}/tests/Makefile $t/tests/
sed -e 's,--sysroot=${STAGING_DIR_TARGET},,g' \
-e 's|${DEBUG_PREFIX_MAP}||g' \
-e 's:${HOSTTOOLS_DIR}/::g' \
-e 's:${RECIPE_SYSROOT_NATIVE}::g' \
-e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \
-e 's|^Makefile:|_Makefile:|' \
-e 's|bash|sh|' \
-e 's|^top_srcdir = \(.*\)|top_srcdir = ..\/|' \
-e 's|^srcdir = \(.*\)|srcdir = .|' \
-e 's|"`$(built_programs)`"|diff|' \
-e 's|gawk|awk|g' \
-i $t/tests/Makefile
}
|
