blob: 4ba919f7febbaa4aca07321f9cc0a30ef5987074 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
DESCRIPTION = "Package of environment files for SDK"
LIC_FILES_CHKSUM = "file://${POKYBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
file://${POKYBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
LICENSE = "MIT"
PR = "r1"
EXCLUDE_FROM_WORLD = "1"
inherit toolchain-scripts
# get target config site before inheritting cross-canadian
TARGET_CONFIG_SITE := "${@siteinfo_get_files(d)}"
SDK_DIR = "${WORKDIR}/sdk"
SDK_OUTPUT = "${SDK_DIR}/image"
SDKTARGETSYSROOT = "${SDKPATH}/sysroots/${TARGET_SYS}"
inherit cross-canadian
do_generate_content[nostamp] = "1"
do_generate_content() {
rm -rf ${SDK_OUTPUT}
mkdir -p ${SDK_OUTPUT}/${SDKPATH}
siteconfig=${SDK_OUTPUT}/${SDKPATH}/site-config-${OLD_MULTIMACH_TARGET_SYS}
touch $siteconfig
for sitefile in ${TARGET_CONFIG_SITE} ; do
cat $sitefile >> $siteconfig
done
toolchain_create_sdk_env_script_for_installer
# Add version information
versionfile=${SDK_OUTPUT}/${SDKPATH}/version-${OLD_MULTIMACH_TARGET_SYS}
touch $versionfile
echo 'Distro: ${DISTRO}' >> $versionfile
echo 'Distro Version: ${DISTRO_VERSION}' >> $versionfile
echo 'Metadata Revision: ${METADATA_REVISION}' >> $versionfile
echo 'Timestamp: ${DATETIME}' >> $versionfile
}
addtask generate_content before do_install after do_compile
do_install[nostamp] = "1"
do_install() {
install -d ${D}/${SDKPATH}
install -m 0644 -t ${D}/${SDKPATH} ${SDK_OUTPUT}/${SDKPATH}/*
}
PN = "meta-environment-${TRANSLATED_TARGET_ARCH}"
PACKAGES = "${PN}"
FILES_${PN}= " \
${SDKPATH}/* \
"
do_fetch[noexec] = "1"
do_unpack[noexec] = "1"
do_patch[noexec] = "1"
do_configure[noexec] = "1"
do_compile[noexec] = "1"
do_populage_sysroot[noexec] = "1"
|
