summaryrefslogtreecommitdiffstats
path: root/meta/classes/mime.bbclass
blob: bb99bc35cb62b8cb195fee001a43f5396b8a35f4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
#
# This class is used by recipes installing mime types
#

DEPENDS += "${@bb.utils.contains('BPN', 'shared-mime-info', '', 'shared-mime-info', d)}"
PACKAGE_WRITE_DEPS += "shared-mime-info-native"
MIMEDIR = "${datadir}/mime"

mime_postinst() {
if [ "x$D" != "x" ]; then
	$INTERCEPT_DIR/postinst_intercept update_mime_database ${PKG} \
		mlprefix=${MLPREFIX} \
		mimedir=${MIMEDIR}
else
	echo "Updating MIME database... this may take a while."
	update-mime-database $D${MIMEDIR}
fi
}

mime_postrm() {
if [ "x$D" != "x" ]; then
	$INTERCEPT_DIR/postinst_intercept update_mime_database ${PKG} \
		mlprefix=${MLPREFIX} \
		mimedir=${MIMEDIR}
else
	echo "Updating MIME database... this may take a while."
	# $D${MIMEDIR}/packages belong to package shared-mime-info-data,
	# packages like libfm-mime depend on shared-mime-info-data.
	# after shared-mime-info-data uninstalled, $D${MIMEDIR}/packages
	# is removed, but update-mime-database need this dir to update
	# database, workaround to create one and remove it later
	if [ ! -d $D${MIMEDIR}/packages ]; then
		mkdir -p $D${MIMEDIR}/packages
		update-mime-database $D${MIMEDIR}
		rmdir --ignore-fail-on-non-empty $D${MIMEDIR}/packages
	else
		update-mime-database $D${MIMEDIR}
fi
fi
}

python populate_packages_append () {
    packages = d.getVar('PACKAGES').split()
    pkgdest =  d.getVar('PKGDEST')
    mimedir = d.getVar('MIMEDIR')

    for pkg in packages:
        mime_packages_dir = '%s/%s%s/packages' % (pkgdest, pkg, mimedir)
        mimes_types_found = False
        if os.path.exists(mime_packages_dir):
            for f in os.listdir(mime_packages_dir):
                if f.endswith('.xml'):
                    mimes_types_found = True
                    break
        if mimes_types_found:
            bb.note("adding mime postinst and postrm scripts to %s" % pkg)
            postinst = d.getVar('pkg_postinst_%s' % pkg)
            if not postinst:
                postinst = '#!/bin/sh\n'
            postinst += d.getVar('mime_postinst')
            d.setVar('pkg_postinst_%s' % pkg, postinst)
            postrm = d.getVar('pkg_postrm_%s' % pkg)
            if not postrm:
                postrm = '#!/bin/sh\n'
            postrm += d.getVar('mime_postrm')
            d.setVar('pkg_postrm_%s' % pkg, postrm)
            if pkg != 'shared-mime-info-data':
                bb.note("adding shared-mime-info-data dependency to %s" % pkg)
                d.appendVar('RDEPENDS_' + pkg, " " + d.getVar('MLPREFIX')+"shared-mime-info-data")
}