From fff02c7c2c1c6ab0ceb1f888134d381d8b612884 Mon Sep 17 00:00:00 2001
From: Xiaofeng Yan <xiaofeng.yan@windriver.com>
Date: Mon, 7 Nov 2011 19:19:54 +0800
Subject: qmmp: update to 0.5.2

qmmp: remove old recipe and add new recipe

Use do_split_package for each grouping and name them correctly besides updating package.
The format to name plugins of qmmp:
qmmp-plugin-<group>-<library>   with the Description: Qmmp<Group>  plugin for %s"

Signed-off-by: Xiaofeng Yan <xiaofeng.yan@windriver.com>

Fix dESCRIPTION -> DESCRIPTION

Signed-off-by: Saul Wold <sgw@linux.intel.com>
---
 meta/recipes-qt/qt-apps/qmmp_0.5.2.bb | 54 +++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 meta/recipes-qt/qt-apps/qmmp_0.5.2.bb

(limited to 'meta/recipes-qt/qt-apps/qmmp_0.5.2.bb')

diff --git a/meta/recipes-qt/qt-apps/qmmp_0.5.2.bb b/meta/recipes-qt/qt-apps/qmmp_0.5.2.bb
new file mode 100644
index 0000000000..b3ecc457bc
--- /dev/null
+++ b/meta/recipes-qt/qt-apps/qmmp_0.5.2.bb
@@ -0,0 +1,54 @@
+DESCRIPTION = "Qmmp (Qt-based Multimedia Player) is an audio-player, written with help of Qt library"
+HOMEPAGE = "http://qmmp.ylsoftware.com"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=393a5ca445f6965873eca0259a17f833"
+SECTION = "multimedia"
+
+PR = "r0"
+
+DEPENDS = "taglib libmad libvorbis libogg alsa-lib"
+
+SRC_URI = "http://qmmp.ylsoftware.com/files/${BPN}-${PV}.tar.bz2"
+
+SRC_URI[md5sum] = "20852f3cce3471bfc5affa9b2e947dc6"
+SRC_URI[sha256sum] = "6391dec020d2a381d7f4b7890fae6c49eadf88b3c9aef571fe3c5e96140822ec"
+
+
+inherit qmake2 cmake qt4x11
+
+export EXTRA_OECMAKE = "-DQT_QMAKE_EXECUTABLE=${OE_QMAKE_QMAKE} \
+                        -DQT_LRELEASE_EXECUTABLE=${OE_QMAKE_LRELEASE} \
+                        -DQT_MOC_EXECUTABLE=${OE_QMAKE_MOC} \
+                        -DQT_UIC_EXECUTABLE=${OE_QMAKE_UIC} \
+                        -DQT_RCC_EXECUTABLE=${OE_QMAKE_RCC} \
+                        -DQT_LIBRARY_DIR=${OE_QMAKE_LIBDIR_QT} \
+                        -DQT_HEADERS_DIR=${OE_QMAKE_INCDIR_QT} \
+                        -DQT_QTCORE_INCLUDE_DIR=${OE_QMAKE_INCDIR_QT}/QtCore \
+                        "
+PACKAGES_DYNAMIC = "qmmp-plugin-* "
+
+
+python populate_packages_prepend () {
+	import os
+	qmmp_libdir = bb.data.expand('${libdir}/qmmp', d)
+	gd = bb.data.expand('${D}/${libdir}/qmmp', d)
+	plug_dirs = os.listdir(gd)
+
+	for plug_dir in plug_dirs:
+		g_plug_dir = os.path.join(qmmp_libdir,plug_dir)
+		do_split_packages(d, g_plug_dir, '^lib(.*)\.so$', 'qmmp-plugin-' + plug_dir.lower() + '-%s', 'Qmmp' + plug_dir  + 'plugin for %s')
+} 
+
+FILES_${PN} = "\
+		${bindir}/qmmp \
+                ${libdir}/lib*${SOLIBS} \ 
+		${datadir}/icons/* \
+                ${datadir}/qmmp/images/* \
+                ${datadir}/applications/* \
+		"
+
+FILES_${PN}-dbg += "\
+                ${libdir}/qmmp/*/.debug/* \
+               "
+
+RDEPENDS_${PN} += "taglib alsa-lib libmad curl"
-- 
cgit 1.2.3-korg