aboutsummaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/glibc/glibc-testsuite_2.29.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-core/glibc/glibc-testsuite_2.29.bb')
-rw-r--r--meta/recipes-core/glibc/glibc-testsuite_2.29.bb51
1 files changed, 51 insertions, 0 deletions
diff --git a/meta/recipes-core/glibc/glibc-testsuite_2.29.bb b/meta/recipes-core/glibc/glibc-testsuite_2.29.bb
new file mode 100644
index 00000000000..665619377d3
--- /dev/null
+++ b/meta/recipes-core/glibc/glibc-testsuite_2.29.bb
@@ -0,0 +1,51 @@
+require glibc_${PV}.bb
+
+# handle PN differences
+FILESEXTRAPATHS_prepend := "${THISDIR}/glibc:"
+
+# strip provides
+PROVIDES = ""
+# setup depends
+INHIBIT_DEFAULT_DEPS = ""
+
+DEPENDS += "glibc-locale libgcc gcc-runtime"
+
+# remove the initial depends
+DEPENDS_remove = "libgcc-initial"
+
+inherit qemu
+
+SRC_URI += "file://check-test-wrapper"
+
+DEPENDS += "${@'qemu-native' if d.getVar('BUILD_TEST_TARGET') == 'user' else ''}"
+
+BUILD_TEST_TARGET ??= "user"
+BUILD_TEST_HOST ??= "localhost"
+BUILD_TEST_HOST_USER ??= "root"
+BUILD_TEST_HOST_PORT ??= "2222"
+
+do_check[dirs] += "${B}"
+do_check[nostamp] = "1"
+do_check () {
+ chmod 0755 ${WORKDIR}/check-test-wrapper
+
+ # clean out previous test results
+ oe_runmake tests-clean
+ # makefiles don't clean entirely (and also sometimes fails due to too many args)
+ find ${B} -type f -name "*.out" -delete
+ find ${B} -type f -name "*.test-result" -delete
+ find ${B}/catgets -name "*.cat" -delete
+ find ${B}/conform -name "symlist-*" -delete
+ [ ! -e ${B}/timezone/testdata ] || rm -rf ${B}/timezone/testdata
+
+ oe_runmake -i \
+ QEMU_SYSROOT="${RECIPE_SYSROOT}" \
+ QEMU_OPTIONS="${@qemu_target_binary(d)} ${QEMU_OPTIONS}" \
+ SSH_HOST="${BUILD_TEST_HOST}" \
+ SSH_HOST_USER="${BUILD_TEST_HOST_USER}" \
+ SSH_HOST_PORT="${BUILD_TEST_HOST_PORT}" \
+ test-wrapper="${WORKDIR}/check-test-wrapper ${BUILD_TEST_TARGET}" \
+ check
+}
+addtask do_check after do_compile
+