aboutsummaryrefslogtreecommitdiffstats
path: root/meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.19.bb
diff options
context:
space:
mode:
authorCristiana Voicu <cristiana.voicu@intel.com>2013-10-30 17:35:50 +0200
committerSaul Wold <sgw@linux.intel.com>2013-10-31 23:57:04 -0700
commita896ac91109ab3f2a6b8c7253c6da3e3e60203b6 (patch)
treee7de42f545ecbc2e5d5cbd11a999adce055dc234 /meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.19.bb
parentb9778975db410b8cd01ef6854c7cd3ea22a0b5b7 (diff)
downloadopenembedded-core-contrib-a896ac91109ab3f2a6b8c7253c6da3e3e60203b6.tar.gz
rxvt-unicode: upgrade to 9.19
Signed-off-by: Cristiana Voicu <cristiana.voicu@intel.com> Signed-off-by: Saul Wold <sgw@linux.intel.com>
Diffstat (limited to 'meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.19.bb')
-rw-r--r--meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.19.bb64
1 files changed, 64 insertions, 0 deletions
diff --git a/meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.19.bb b/meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.19.bb
new file mode 100644
index 0000000000..c67adbb602
--- /dev/null
+++ b/meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.19.bb
@@ -0,0 +1,64 @@
+SECTION = "x11/utils"
+DESCRIPTION = "rxvt-unicode is a clone of the well known \
+terminal emulator rxvt, modified to store text in Unicode \
+(either UCS-2 or UCS-4) and to use locale-correct input and \
+output. It also supports mixing multiple fonts at the \
+same time, including Xft fonts."
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+ file://src/main.C;beginline=1;endline=31;md5=775485398a09fa7aee6f90464af88432"
+
+DEPENDS = "virtual/libx11 libxt libxft gdk-pixbuf"
+
+SRC_URI = "http://dist.schmorp.de/rxvt-unicode/Attic/rxvt-unicode-${PV}.tar.bz2 \
+ file://xwc.patch \
+ file://rxvt.desktop \
+ file://rxvt.png"
+
+SRC_URI[md5sum] = "45ad197eb9b5a840c0f65e3a8131921c"
+SRC_URI[sha256sum] = "d9237cf1973af461ecbeeb708e4d00893294771558e8338b4f33418ed52d3241"
+
+inherit autotools update-alternatives
+
+PROVIDES = "virtual/x-terminal-emulator"
+ALTERNATIVE_${PN} = "x-terminal-emulator"
+ALTERNATIVE_TARGET[x-terminal-emulator] = "${bindir}/rxvt"
+
+CFLAGS_append = " -fpermissive"
+
+EXTRA_OECONF = "--enable-menubar --enable-xim \
+ --enable-utmp --enable-wtmp --enable-lastlog \
+ --disable-strings --with-term=rxvt --enable-keepscrolling \
+ --enable-xft --with-name=rxvt --enable-frills \
+ --enable-swapscreen --enable-transparency \
+ --with-codesets=eu \
+ --enable-cursor-blink --enable-pointer-blank \
+ --enable-text-blink --enable-rxvt-scroll \
+ --enable-combining --enable-shared \
+ --enable-xgetdefault \
+ --disable-perl \
+ --with-x=${STAGING_DIR_HOST}${prefix}"
+
+do_configure_prepend () {
+ if [ ! -e ${S}/acinclude.m4 ]; then
+ cp ${S}/aclocal.m4 ${S}/acinclude.m4
+ fi
+}
+
+do_compile_prepend () {
+ echo '#define UTMP_FILE "${localstatedir}/run/utmp"' >> config.h
+ echo '#define WTMP_FILE "${localstatedir}/log/wtmp"' >> config.h
+ echo '#define LASTLOG_FILE "${localstatedir}/log/lastlog"' >> config.h
+ echo '#define HAVE_XLOCALE 1' >> config.h
+}
+
+do_install_append () {
+ install -d ${D}/${datadir}
+ install -d ${D}/${datadir}/applications
+ install -d ${D}/${datadir}/pixmaps/
+
+ install -m 0644 ${WORKDIR}/rxvt.png ${D}/${datadir}/pixmaps
+ install -m 0644 ${WORKDIR}/rxvt.desktop ${D}/${datadir}/applications
+}
+
+FILES_${PN} += "${datadir}/applications/rxvt.desktop ${datadir}/pixmaps/rxvt.png"