qt5: import recipes which often reproduce Yocto #12434 from meta-qt5

* just temporary to make it easier to reproduce, import big part of
  meta-qt5
* qtquickcontrols-5.9.5+gitAUTOINC+75e9561d4f-r0 do_package_qa: QA Issue: qtquickcontrols: /qtquickcontrols-qmlplugins/usr/lib/qml/QtQuick/Controls/Styles/Base/TreeViewStyle.qml is owned by uid 1101, which is the same as the user running bitbake. This may be due to host contamination [host-user-contaminated]
* to reproduce this you can try to use something like this:
  export COMP=qtquickcontrols; for i in `seq -w 1 999`; do echo $i; bitbake -v -v -DDDD -f -c package ${COMP} 2>${COMP}-logerr.$i >${COMP}-log.$i; bitbake  -v -v -DDDD -f -c package_qa ${COMP} 2>${COMP}-logerr.qa.$i >${COMP}-log.qa.$i || { cp -ra BUILD/work/i586-oe-linux/${COMP}/ ${COMP}-workdir-$i; bitbake -c cleansstate ${COMP} ; } done

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

1 files changed, 35 insertions, 0 deletions

diff --git a/meta/recipes-qt/qt5/qtdeclarative_git.bb b/meta/recipes-qt/qt5/qtdeclarative_git.bb
new file mode 100644
index 0000000000..d6f468fc2d
--- /dev/null
+++ b/meta/recipes-qt/qt5/qtdeclarative_git.bb
@@ -0,0 +1,35 @@
+require qt5.inc
+require qt5-git.inc
+require qt5-ptest.inc
+
+HOMEPAGE = "http://www.qt.io"
+LICENSE = "GFDL-1.3 & BSD & ( GPL-3.0 & The-Qt-Company-GPL-Exception-1.0 | The-Qt-Company-Commercial ) & ( GPL-2.0+ | LGPL-3.0 | The-Qt-Company-Commercial )"
+LIC_FILES_CHKSUM = " \
+    file://LICENSE.LGPL3;md5=e6a600fd5e1d9cbde2d983680233ad02 \
+    file://LICENSE.GPL2;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+    file://LICENSE.GPL3;md5=d32239bcb673463ab874e80d47fae504 \
+    file://LICENSE.GPL3-EXCEPT;md5=763d8c535a234d9a3fb682c7ecb6c073 \
+    file://LICENSE.FDL;md5=6d9f2a9af4c8b8c3c769f6cc1b6aaf7e \
+"
+
+DEPENDS += "qtbase"
+
+PACKAGECONFIG ??= "qtxmlpatterns"
+PACKAGECONFIG[qtxmlpatterns] = ",,qtxmlpatterns"
+
+do_configure_prepend() {
+    # disable qtxmlpatterns test if it isn't enabled by PACKAGECONFIG
+    sed -e 's/^\(qtHaveModule(xmlpatterns)\)/OE_QTXMLPATTERNS_ENABLED:\1/' -i ${S}/src/imports/imports.pro
+    sed -e 's/^\(!qtHaveModule(xmlpatterns)\)/!OE_QTXMLPATTERNS_ENABLED|\1/' -i ${S}/tests/auto/quick/quick.pro
+}
+
+do_install_append_class-nativesdk() {
+    # qml files not needed in nativesdk
+    rm -rf ${D}${OE_QMAKE_PATH_QML}
+}
+
+EXTRA_QMAKEVARS_PRE += "${@bb.utils.contains('PACKAGECONFIG', 'qtxmlpatterns', 'CONFIG+=OE_QTXMLPATTERNS_ENABLED', '', d)}"
+
+SRCREV = "3e91062877c0853aff693799bc5e33cdf7aaad42"
+
+BBCLASSEXTEND =+ "native nativesdk"