aboutsummaryrefslogtreecommitdiffstats
path: root/meta/recipes-qt/qt-apps/qmmp_0.7.7.bb
diff options
context:
space:
mode:
authorHongxu Jia <hongxu.jia@windriver.com>2014-06-17 15:01:07 +0800
committerRichard Purdie <richard.purdie@linuxfoundation.org>2014-06-17 17:55:08 +0100
commit55b6d5fac389f55089018574cc2b4ef8217f1b0d (patch)
treecb7739dbb4eac9340f0c9a0e9587bc961b1b8d1b /meta/recipes-qt/qt-apps/qmmp_0.7.7.bb
parentee3d6b819160d6a9a1e474e6a9669f9ca2a3b5a3 (diff)
downloadopenembedded-core-contrib-55b6d5fac389f55089018574cc2b4ef8217f1b0d.tar.gz
openembedded-core-contrib-55b6d5fac389f55089018574cc2b4ef8217f1b0d.tar.bz2
openembedded-core-contrib-55b6d5fac389f55089018574cc2b4ef8217f1b0d.zip
qmmp: upgrade to 0.7.7
Build: 1) Add LICENSE_FLAGS_WHITELIST += "commercial" to local.conf 2) bitbake qmmp Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-qt/qt-apps/qmmp_0.7.7.bb')
-rw-r--r--meta/recipes-qt/qt-apps/qmmp_0.7.7.bb77
1 files changed, 77 insertions, 0 deletions
diff --git a/meta/recipes-qt/qt-apps/qmmp_0.7.7.bb b/meta/recipes-qt/qt-apps/qmmp_0.7.7.bb
new file mode 100644
index 0000000000..9725b42f66
--- /dev/null
+++ b/meta/recipes-qt/qt-apps/qmmp_0.7.7.bb
@@ -0,0 +1,77 @@
+SUMMARY = "Qt-based Multimedia Player"
+DESCRIPTION = "Qmmp is an audio player, written with the help of the Qt library. The user interface is similar to Winamp or XMMS."
+HOMEPAGE = "http://qmmp.ylsoftware.com"
+LICENSE = "GPLv2"
+LICENSE_FLAGS = "commercial"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+SECTION = "multimedia"
+
+DEPENDS = "taglib libmad libvorbis libogg alsa-lib libsndfile1 libsamplerate0 curl"
+
+SRC_URI = "http://qmmp.ylsoftware.com/files/${BPN}-${PV}.tar.bz2 \
+ file://no-host-paths.patch \
+ "
+
+SRC_URI[md5sum] = "9376b5d535ed540e97bdff79b42607ae"
+SRC_URI[sha256sum] = "dda66bf60121a8a2cb7175b16b3b948099f8c119ee9a11c671555e8c38caa387"
+
+inherit cmake qt4x11
+
+QMMP_PLUGIN_OPTIONS ??= "\
+ -DUSE_MMS:BOOL=FALSE \
+ -DUSE_MPC:BOOL=FALSE \
+ -DUSE_MODPLUG:BOOL=FALSE \
+ -DUSE_WAVPACK:BOOL=FALSE \
+ -DUSE_FFMPEG:BOOL=FALSE \
+ -DUSE_AAC:BOOL=FALSE \
+ -DUSE_CDA:BOOL=FALSE \
+ -DUSE_MIDI:BOOL=FALSE \
+ -DUSE_GME:BOOL=FALSE \
+ -DUSE_OSS4:BOOL=FALSE \
+ -DUSE_JACK:BOOL=FALSE \
+ -DUSE_BS2B:BOOL=FALSE \
+ -DUSE_PROJECTM:BOOL=FALSE \
+ -DUSE_ENCA:BOOL=FALSE \
+ "
+
+export EXTRA_OECMAKE = "-DQT_QMAKE_EXECUTABLE=${OE_QMAKE_QMAKE} \
+ -DQT_LRELEASE_EXECUTABLE=${OE_QMAKE_LRELEASE} \
+ -DQT_MOC_EXECUTABLE=${OE_QMAKE_MOC} \
+ -DQT_UIC_EXECUTABLE=${OE_QMAKE_UIC} \
+ -DQT_RCC_EXECUTABLE=${OE_QMAKE_RCC} \
+ -DQT_LIBRARY_DIR=${OE_QMAKE_LIBDIR_QT} \
+ -DQT_HEADERS_DIR=${OE_QMAKE_INCDIR_QT} \
+ -DQT_QTCORE_INCLUDE_DIR=${OE_QMAKE_INCDIR_QT}/QtCore \
+ ${QMMP_PLUGIN_OPTIONS} \
+ "
+
+do_configure() {
+ # Ensure we get the cmake configure and not qmake
+ cmake_do_configure
+}
+
+PACKAGES_DYNAMIC += "^qmmp-plugin-.* "
+
+python populate_packages_prepend () {
+ qmmp_libdir = d.expand('${libdir}/qmmp')
+ gd = d.expand('${D}/${libdir}/qmmp')
+ plug_dirs = os.listdir(gd)
+
+ for plug_dir in plug_dirs:
+ g_plug_dir = os.path.join(qmmp_libdir,plug_dir)
+ do_split_packages(d, g_plug_dir, '^lib(.*)\.so$', 'qmmp-plugin-' + plug_dir.lower() + '-%s', 'Qmmp ' + plug_dir + ' plugin for %s')
+}
+
+FILES_${PN} = "\
+ ${bindir}/qmmp \
+ ${libdir}/lib*${SOLIBS} \
+ ${datadir}/icons/* \
+ ${datadir}/qmmp/images/* \
+ ${datadir}/applications/* \
+ "
+
+FILES_${PN}-dbg += "\
+ ${libdir}/qmmp/*/.debug/* \
+ "
+
+RDEPENDS_${PN} += "taglib alsa-lib libmad curl"