glib-2.0: upgrade to 2.32.1

* g_once_init_enter.patch shouldn't be needed after upstream commit
  794c1a30bc27b4c8d77537813acb1213d5ac80f2

* LIC_FILES_CHKSUM change is only because PCRE was upgraded and now
  pcre.h says "Copyright (c) 1997-2012 University of Cambridge" instead
  of 2010 and COPYING file
  "Please see the file LICENCE in the PCRE distribution for licensing
  details."  but LICENSE file is not part of glib distribution (but still
  BSD in standalone PCRE)

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

1 files changed, 52 insertions, 0 deletions

diff --git a/meta/recipes-core/glib-2.0/glib-2.0_2.32.1.bb b/meta/recipes-core/glib-2.0/glib-2.0_2.32.1.bb
new file mode 100644
index 0000000000..a62c91a3c2
--- /dev/null
+++ b/meta/recipes-core/glib-2.0/glib-2.0_2.32.1.bb
@@ -0,0 +1,52 @@
+require glib.inc
+
+PR = "r2"
+PE = "1"
+
+DEPENDS += "libffi python-argparse-native zlib"
+DEPENDS_virtclass-native += "libffi-native python-argparse-native"
+DEPENDS_virtclass-nativesdk += "libffi-nativesdk python-argparse-native zlib-nativesdk"
+
+SHRT_VER = "${@d.getVar('PV',1).split('.')[0]}.${@d.getVar('PV',1).split('.')[1]}"
+
+SRC_URI = "${GNOME_MIRROR}/glib/${SHRT_VER}/glib-${PV}.tar.xz \
+           file://configure-libtool.patch \
+           file://60_wait-longer-for-threads-to-die.patch \
+           file://glib-2.0_fix_for_x32.patch \
+           file://nodbus.patch \
+          "
+SRC_URI[md5sum] = "032c7cf9868c9aa186b490b155a41144"
+SRC_URI[sha256sum] = "484d5b7fc09f3fa398355adaf74b369768f5859866c299f229c99721990f8398"
+
+SRC_URI_append_virtclass-native = " file://glib-gettextize-dir.patch"
+BBCLASSEXTEND = "native nativesdk"
+
+PERLPATH = "${bindir}/env perl"
+PERLPATH_virtclass-native = "/usr/bin/env perl"
+PERLPATH_virtclass-nativesdk = "/usr/bin/env perl"
+
+do_configure_prepend() {
+  # missing ${topdir}/gtk-doc.make and --disable-gtk-doc* is not enough, because it calls gtkdocize (not provided by gtk-doc-native)
+  sed -i '/^docs/d' ${S}/configure.ac
+  sed -i 's/SUBDIRS = . m4macros glib gmodule gthread gobject gio tests po docs/SUBDIRS = . m4macros glib gmodule gthread gobject gio tests po/g' ${S}/Makefile.am
+  sed -i -e "s:TEST_PROGS += gdbus-serialization::g"  ${S}/gio/tests/Makefile.am
+}
+
+do_install_append() {
+  # remove some unpackaged files
+  rm -f ${D}${libdir}/gdbus-2.0/codegen/*.pyc
+  rm -f ${D}${libdir}/gdbus-2.0/codegen/*.pyo
+  # and empty dirs
+  rmdir ${D}${libdir}/gio/modules/
+  rmdir ${D}${libdir}/gio/
+
+  # Some distros have both /bin/perl and /usr/bin/perl, but we set perl location
+  # for target as /usr/bin/perl, so fix it to /usr/bin/perl.
+  if [ -f ${D}${bindir}/glib-mkenums ]; then
+    sed -i -e '1s,#!.*perl,#! ${PERLPATH},' ${D}${bindir}/glib-mkenums
+  fi
+}
+
+PACKAGES += "${PN}-codegen"
+FILES_${PN}-codegen = "${libdir}/gdbus-2.0/codegen/*.py"
+FILES_${PN} += "${datadir}/glib-2.0/gettext/mkinstalldirs ${datadir}/glib-2.0/gettext/po/Makefile.in.in"