base-passwd: upgrade to 3.5.28

Disable docs creation for now it uses po4a and sgmltools-lite which are
not currently part of OE-Core

Signed-off-by: Saul Wold <sgw@linux.intel.com>

1 files changed, 0 insertions, 95 deletions

diff --git a/meta/recipes-core/base-passwd/base-passwd_3.5.26.bb b/meta/recipes-core/base-passwd/base-passwd_3.5.26.bb
deleted file mode 100644
index 4d94dcca65..0000000000
--- a/meta/recipes-core/base-passwd/base-passwd_3.5.26.bb
+++ /dev/null
@@ -1,95 +0,0 @@
-SUMMARY = "Base system master password/group files."
-DESCRIPTION = "The master copies of the user database files (/etc/passwd and /etc/group).  The update-passwd tool is also provided to keep the system databases synchronized with these master files."
-SECTION = "base"
-PR = "r2"
-LICENSE = "GPLv2+"
-LIC_FILES_CHKSUM = "file://COPYING;md5=eb723b61539feef013de476e68b5c50a"
-
-SRC_URI = "${DEBIAN_MIRROR}/main/b/base-passwd/base-passwd_${PV}.tar.gz \
-           file://add_shutdown.patch \
-           file://nobash.patch \
-           file://input.patch"
-
-SRC_URI[md5sum] = "74245e5c21dc74d9675c77cd8dfa02e6"
-SRC_URI[sha256sum] = "258a78317aa563143d10375c6e1e63a60898e503887f00fffd70b6b297c1b429"
-
-inherit autotools
-
-SSTATEPOSTINSTFUNCS += "base_passwd_sstate_postinst"
-
-do_install () {
-	install -d -m 755 ${D}${sbindir}
-	install -o root -g root -p -m 755 ${B}/update-passwd ${D}${sbindir}/
-	install -d -m 755 ${D}${mandir}/man8 ${D}${mandir}/pl/man8
-	install -p -m 644 ${S}/man/update-passwd.8 ${D}${mandir}/man8/
-	install -p -m 644 ${S}/man/update-passwd.pl.8 \
-		${D}${mandir}/pl/man8/update-passwd.8
-	gzip -9 ${D}${mandir}/man8/* ${D}${mandir}/pl/man8/*
-	install -d -m 755 ${D}${datadir}/base-passwd
-	sed -i 's#:/root:#:${ROOT_HOME}:#' ${S}/passwd.master
-	install -o root -g root -p -m 644 ${S}/passwd.master ${D}${datadir}/base-passwd/
-	install -o root -g root -p -m 644 ${S}/group.master ${D}${datadir}/base-passwd/
-
-	install -d -m 755 ${D}${docdir}/${BPN}
-	install -p -m 644 ${S}/debian/changelog ${D}${docdir}/${BPN}/
-	gzip -9 ${D}${docdir}/${BPN}/*
-	install -p -m 644 ${S}/README ${D}${docdir}/${BPN}/
-	install -p -m 644 ${S}/debian/copyright ${D}${docdir}/${BPN}/
-}
-
-base_passwd_sstate_postinst() {
-	if [ "${BB_CURRENTTASK}" = "populate_sysroot" -o "${BB_CURRENTTASK}" = "populate_sysroot_setscene" ]
-	then
-		# Staging does not copy ${sysconfdir} files into the
-		# target sysroot, so we need to do so manually. We
-		# put these files in the target sysroot so they can
-		# be used by recipes which use custom user/group
-		# permissions.
-		install -d -m 755 ${STAGING_DIR_TARGET}${sysconfdir}
-		install -p -m 644 ${STAGING_DIR_TARGET}${datadir}/base-passwd/passwd.master ${STAGING_DIR_TARGET}${sysconfdir}/passwd
-		install -p -m 644 ${STAGING_DIR_TARGET}${datadir}/base-passwd/group.master ${STAGING_DIR_TARGET}${sysconfdir}/group
-	fi
-}
-
-python populate_packages_prepend() {
-    # Add in the preinst function for ${PN}
-    # We have to do this here as prior to this, passwd/group.master
-    # would be unavailable. We need to create these files at preinst
-    # time before the files from the package may be available, hence
-    # storing the data from the files in the preinst directly.
-
-    f = open(d.expand("${STAGING_DATADIR}/base-passwd/passwd.master"), 'r')
-    passwd = "".join(f.readlines())
-    f.close()
-    f = open(d.expand("${STAGING_DATADIR}/base-passwd/group.master"), 'r')
-    group = "".join(f.readlines())
-    f.close()
-
-    preinst = """#!/bin/sh
-mkdir -p $D${sysconfdir}
-if [ ! -e $D${sysconfdir}/passwd ]; then
-\tcat << EOF > $D${sysconfdir}/passwd
-""" + passwd + """EOF
-fi
-if [ ! -e $D${sysconfdir}/group ]; then
-\tcat << EOF > $D${sysconfdir}/group
-""" + group + """EOF
-fi
-"""
-    d.setVar('pkg_preinst_${PN}', preinst)
-}
-
-addtask do_package after do_populate_sysroot
-
-ALLOW_EMPTY_${PN} = "1"
-
-PACKAGES =+ "${PN}-update"
-FILES_${PN}-update = "${sbindir}/* ${datadir}/${PN}"
-
-pkg_postinst_${PN}-update () {
-#!/bin/sh
-if [ -n "$D" ]; then
-	exit 0
-fi
-${sbindir}/update-passwd
-}