python-cryptography,-vectors: add 0.8.1

python-cryptography is required by python-pyopenssl >= 0.14

Includes python-cryptography-vectors package for ptest

Over 75k unit tests (100% coverage):
	* tested on nuc (x86) and beaglebone (arm) hardware.
	** will overload ram on default qemux86/qemuarm

(From meta-openembedded commit: c346f605766754c02004478371f22609f15ecd1a)

Signed-off-by: Tim Orling <TicoTimo@gmail.com>
Signed-off-by: Tim Orling <ticotimo@gmail.com>

3 files changed, 62 insertions, 0 deletions

diff --git a/recipes-devtools/python/python-cryptography-vectors_0.8.1.bb b/recipes-devtools/python/python-cryptography-vectors_0.8.1.bb
new file mode 100644
index 0000000..a9b64ed
--- /dev/null
+++ b/recipes-devtools/python/python-cryptography-vectors_0.8.1.bb
@@ -0,0 +1,14 @@
+SUMMARY = "Test vectors for the cryptography package."
+SECTION = "devel/python"
+LICENSE = "Apache-2.0 | BSD"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=8c3617db4fb6fae01f1d253ab91511e4"
+DEPENDS = "python-cryptography"
+SRCNAME = "cryptography_vectors"
+
+SRC_URI = "https://pypi.python.org/packages/source/c/cryptography-vectors/${SRCNAME}-${PV}.tar.gz"
+S = "${WORKDIR}/${SRCNAME}-${PV}"
+
+SRC_URI[md5sum] = "04fcfcc61aee62e3b4beb1740cd120ac"
+SRC_URI[sha256sum] = "4a69e66026bfce4b97f75e72fe262f5e8f71daddc081f6608e5b0db89e552504"
+
+inherit setuptools
diff --git a/recipes-devtools/python/python-cryptography/run-ptest b/recipes-devtools/python/python-cryptography/run-ptest
new file mode 100644
index 0000000..0ba239c
--- /dev/null
+++ b/recipes-devtools/python/python-cryptography/run-ptest
@@ -0,0 +1,2 @@
+#!/bin/sh
+py.test
diff --git a/recipes-devtools/python/python-cryptography_0.8.1.bb b/recipes-devtools/python/python-cryptography_0.8.1.bb
new file mode 100644
index 0000000..41e4acd
--- /dev/null
+++ b/recipes-devtools/python/python-cryptography_0.8.1.bb
@@ -0,0 +1,46 @@
+SUMMARY = "Provides cryptographic recipes and primitives to Python developers"
+SECTION = "devel/python"
+LICENSE = "Apache-2.0 | BSD"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=8c3617db4fb6fae01f1d253ab91511e4"
+DEPENDS += " python-cffi-native python-cffi python-enum34 python-six python-pyasn1"
+SRCNAME = "cryptography"
+
+SRC_URI = "https://pypi.python.org/packages/source/c/${SRCNAME}/${SRCNAME}-${PV}.tar.gz \
+           file://run-ptest \
+"
+S = "${WORKDIR}/${SRCNAME}-${PV}"
+
+SRC_URI[md5sum] = "70dde78a5515abdbfd7a3d58f15689ab"
+SRC_URI[sha256sum] = "f4e041bc83c1be94d87116a7aa201c378b7c6581be4d83994b2da0a84499f73b"
+
+inherit pypi
+
+RDEPENDS_${PN} = "\
+                  python-pyasn1\
+                  python-six\
+                  python-cffi\
+                  python-enum34\
+                  python-setuptools\
+                  python-pycparser\
+                  python-subprocess\
+                  python-threading\
+                  python-numbers\
+                  python-contextlib\
+"
+
+RDEPENDS_${PN}-ptest = "\
+                       ${PN}\
+                       python-pytest\
+                       python-pretend\
+                       python-iso8601\
+                       python-cryptography-vectors\
+"
+
+inherit ptest
+
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/tests
+    cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+    install -d ${D}${PTEST_PATH}/tests/hazmat
+    cp -rf ${S}/tests/hazmat/* ${D}${PTEST_PATH}/tests/hazmat/
+}