blob: 7f087da7ce1d8bb691def793600309fad765aeba (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
SUMMARY = "NVMe management command line interface"
AUTHOR = "Stefan Wiehler <stefan.wiehler@missinglinkelectronics.com>"
HOMEPAGE = "https://github.com/linux-nvme/nvme-cli"
SECTION = "console/utils"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://LICENSE;md5=8264535c0c4e9c6c335635c4026a8022"
DEPENDS = "util-linux"
PV .= "+git${SRCPV}"
SRC_URI = "git://github.com/linux-nvme/nvme-cli.git;branch=master;protocol=https"
SRCREV = "f0e9569df9289d6ee55ba2c23615cc7c73a9b088"
S = "${WORKDIR}/git"
inherit bash-completion systemd
do_install() {
oe_runmake install-spec DESTDIR=${D} PREFIX=${prefix} \
UDEVDIR=${nonarch_base_libdir}/udev SYSTEMDDIR=${systemd_unitdir}
}
pkg_postinst_ontarget:${PN}() {
${sbindir}/nvme gen-hostnqn > ${sysconfdir}/nvme/hostnqn
${bindir}/uuidgen > ${sysconfdir}/nvme/hostid
}
PACKAGES =+ "${PN}-dracut ${PN}-zsh-completion"
FILES:${PN} += "${systemd_system_unitdir}"
FILES:${PN}-dracut = "${nonarch_libdir}/dracut/dracut.conf.d"
FILES:${PN}-zsh-completion = "${datadir}/zsh/site-functions"
RDEPENDS:${PN} = "util-linux-uuidgen"
|
