blob: 58bcb980f537a0af2d6aa2118079e93fa18fe8ff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
SUMMARY = "A sophisticated network protocol analyzer"
HOMEPAGE = "http://www.tcpdump.org/"
LICENSE = "BSD"
LIC_FILES_CHKSUM = "file://LICENSE;md5=1d4b0366557951c84a94fabe3529f867"
SECTION = "console/network"
DEPENDS = "libpcap"
SRC_URI = " \
http://www.tcpdump.org/release/${BP}.tar.gz \
file://configure.patch \
file://unnecessary-to-check-libpcap.patch \
file://tcpdump-configure-dlpi.patch \
file://tcpdump-cross-getaddrinfo.patch \
"
SRC_URI[md5sum] = "dab267ec30216a069747d10314079ec7"
SRC_URI[sha256sum] = "4c88c2a9aeb4047074f344fc9b2b6577b219972d359e192f6d12ccf983a13fd7"
export LIBS=" -lpcap"
inherit autotools-brokensep
CACHED_CONFIGUREVARS = "ac_cv_linux_vers=${ac_cv_linux_vers=2}"
PACKAGECONFIG ??= "openssl ipv6"
PACKAGECONFIG[openssl] = "--with-crypto=yes, --without-openssl --without-crypto, openssl"
PACKAGECONFIG[ipv6] = "--enable-ipv6, --disable-ipv6,"
EXTRA_AUTORECONF += " -I m4"
do_configure_prepend() {
mkdir -p ${S}/m4
if [ -f aclocal.m4 ]; then
mv aclocal.m4 ${S}/m4
fi
# AC_CHECK_LIB(dlpi.. was looking to host /lib
sed -i 's:-L/lib::g' ./configure.in
}
do_configure_append() {
sed -i 's:-L/usr/lib::' ./Makefile
sed -i 's:-Wl,-rpath,${STAGING_LIBDIR}::' ./Makefile
sed -i 's:-I/usr/include::' ./Makefile
}
do_install_append() {
# tcpdump 4.0.0 installs a copy to /usr/sbin/tcpdump.4.0.0
rm -f ${D}${sbindir}/tcpdump.${PV}
}
|
