blob: 596186651538bcd4f9c8078ce2d38ee6933f0806 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
SUMMARY = "Web-based Traffic and Security Network Traffic Monitoring"
DESCRIPTION = "ntopng is a web-based network traffic monitoring application \
released under GPLv3. It is the new incarnation of the original \
ntop written in 1998, and now revamped in terms of performance, \
usability, and features."
SECTION = "console/network"
DEPENDS = "curl libmaxminddb libpcap lua mariadb ndpi json-c rrdtool zeromq"
RDEPENDS_${PN} = "bash redis"
LICENSE = "GPLv3"
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
SRCREV = "5e649a2d1130b4a3ab0c5bb673d615172cc0bdbb"
SRC_URI = "git://github.com/ntop/ntopng.git;protocol=git;branch=4.2-stable \
file://0001-configure.seed-fix-configure-error.patch \
file://0001-configure.seed-fix-host-contamination.patch \
file://0001-Makefile.in-don-t-use-the-internal-lua.patch \
file://0001-autogen.sh-generate-configure.ac-only.patch \
file://0001-configure.seed-not-check-clang-on-host.patch \
file://ntopng.service \
"
S = "${WORKDIR}/git"
# don't use the lua under thirdparty as it supports cross compiling badly
export LUA_LIB = "${STAGING_LIBDIR}/liblua.a"
LDFLAGS_append_mipsarch = " -latomic"
LDFLAGS_append_powerpc = " -latomic"
LDFLAGS_append_riscv32 = " -latomic"
inherit autotools-brokensep gettext systemd
do_install_append() {
install -d ${D}${systemd_unitdir}/system/
install -m 0644 ${WORKDIR}/ntopng.service ${D}${systemd_unitdir}/system
}
FILES_${PN} += "\
${systemd_unitdir}/system/ntopng.service"
FILES_${PN}-doc += "\
/usr/man/man8/ntopng.8"
do_configure_prepend() {
${S}/autogen.sh
}
SYSTEMD_SERVICE_${PN} = "ntopng.service"
|
