From b5767f592890950a3c0914ac34c21f4b0e97e616 Mon Sep 17 00:00:00 2001
From: Stefan Agner <stefan.agner@toradex.com>
Date: Tue, 10 Sep 2019 23:49:19 +0200
Subject: fuse3: add libfuse3 recipe

Add recipe for libfuse version 3 series. Follow the scheme other
distributions use and create a new recipe with 3 in its name.
To avoid conflict with the fuse (2) recipe this recipe does not
provide init scripts/configuration files which automatically load
the fuse kernel driver.

Signed-off-by: Stefan Agner <stefan.agner@toradex.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
---
 .../recipes-support/fuse/fuse3_3.6.2.bb            | 48 ++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 meta-filesystems/recipes-support/fuse/fuse3_3.6.2.bb

(limited to 'meta-filesystems/recipes-support')

diff --git a/meta-filesystems/recipes-support/fuse/fuse3_3.6.2.bb b/meta-filesystems/recipes-support/fuse/fuse3_3.6.2.bb
new file mode 100644
index 0000000000..e65eb08e27
--- /dev/null
+++ b/meta-filesystems/recipes-support/fuse/fuse3_3.6.2.bb
@@ -0,0 +1,48 @@
+SUMMARY = "Implementation of a fully functional filesystem in a userspace program"
+DESCRIPTION = "FUSE (Filesystem in Userspace) is a simple interface for userspace \
+               programs to export a virtual filesystem to the Linux kernel. FUSE \
+               also aims to provide a secure method for non privileged users to \
+               create and mount their own filesystem implementations. \
+              "
+HOMEPAGE = "https://github.com/libfuse/libfuse"
+SECTION = "libs"
+LICENSE = "GPLv2 & LGPLv2"
+LIC_FILES_CHKSUM = "file://GPL2.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+                    file://LGPL2.txt;md5=4fbd65380cdd255951079008b364516c \
+                    file://LICENSE;md5=a55c12a2d7d742ecb41ca9ae0a6ddc66"
+
+SRC_URI = "https://github.com/libfuse/libfuse/releases/download/fuse-${PV}/fuse-${PV}.tar.xz \
+"
+SRC_URI[md5sum] = "1798945aa69434286723b9999a141c7a"
+SRC_URI[sha256sum] = "f45869427575e1e59ab743a67deb57addbf2cb8f9ce431199dbd40ddab71f281"
+
+S = "${WORKDIR}/fuse-${PV}"
+
+UPSTREAM_CHECK_URI = "https://github.com/libfuse/libfuse/releases"
+UPSTREAM_CHECK_REGEX = "fuse\-(?P<pver>3(\.\d+)+).tar.xz"
+
+inherit meson pkgconfig
+
+DEPENDS = "udev"
+
+PACKAGES =+ "fuse3-utils"
+
+RPROVIDES_${PN}-dbg += "fuse3-utils-dbg"
+
+RRECOMMENDS_${PN}_class-target = "kernel-module-fuse fuse3-utils"
+
+FILES_${PN} += "${libdir}/libfuse3.so.*"
+FILES_${PN}-dev += "${libdir}/libfuse3*.la"
+
+EXTRA_OEMESON += " \
+     -Dexamples=false \
+"
+
+# Forbid auto-renaming to libfuse3-utils
+FILES_fuse3-utils = "${bindir} ${base_sbindir}"
+DEBIAN_NOAUTONAME_fuse3-utils = "1"
+DEBIAN_NOAUTONAME_${PN}-dbg = "1"
+
+do_install_append() {
+    rm -rf ${D}${base_prefix}/dev
+}
-- 
cgit 1.2.3-korg