From 8df5248a144dc2e1cdccea4e35286f483a3fcc35 Mon Sep 17 00:00:00 2001
From: Tim Orling <ticotimo@gmail.com>
Date: Tue, 24 Aug 2021 14:10:28 -0700
Subject: python3-cryptography: add 3.4.7 (needs meta-rust)

Add to dynamic-layers/rust-layer

Leave the existing 3.3.2 recipe, which is the last to be able
to be compiled without rustc and python3-setuptools-rust.

RDEPENDS on python3-hypothesis (in oe-core) for ptest so we can
drop the patch for skipping.

Signed-off-by: Tim Orling <ticotimo@gmail.com>
---
 .../python/python3-cryptography/run-ptest          |  2 +
 .../python/python3-cryptography_3.4.7.bb           | 63 ++++++++++++++++++++++
 2 files changed, 65 insertions(+)
 create mode 100644 meta-python/dynamic-layers/rust-layer/recipes-devtools/python/python3-cryptography/run-ptest
 create mode 100644 meta-python/dynamic-layers/rust-layer/recipes-devtools/python/python3-cryptography_3.4.7.bb

diff --git a/meta-python/dynamic-layers/rust-layer/recipes-devtools/python/python3-cryptography/run-ptest b/meta-python/dynamic-layers/rust-layer/recipes-devtools/python/python3-cryptography/run-ptest
new file mode 100644
index 0000000000..0ba239c2a4
--- /dev/null
+++ b/meta-python/dynamic-layers/rust-layer/recipes-devtools/python/python3-cryptography/run-ptest
@@ -0,0 +1,2 @@
+#!/bin/sh
+py.test
diff --git a/meta-python/dynamic-layers/rust-layer/recipes-devtools/python/python3-cryptography_3.4.7.bb b/meta-python/dynamic-layers/rust-layer/recipes-devtools/python/python3-cryptography_3.4.7.bb
new file mode 100644
index 0000000000..2796b01cbf
--- /dev/null
+++ b/meta-python/dynamic-layers/rust-layer/recipes-devtools/python/python3-cryptography_3.4.7.bb
@@ -0,0 +1,63 @@
+SUMMARY = "Provides cryptographic recipes and primitives to python developers"
+HOMEPAGE = "https://cryptography.io/"
+SECTION = "devel/python"
+LICENSE = "Apache-2.0 | BSD"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=bf405a8056a6647e7d077b0e7bc36aba"
+
+LDSHARED += "-pthread"
+
+SRC_URI[sha256sum] = "3d10de8116d25649631977cb37da6cbdd2d6fa0e0281d014a5b7d337255ca713"
+
+SRC_URI += "file://run-ptest"
+
+inherit cargo pypi setuptools3
+
+DEPENDS += " \
+    ${PYTHON_PN}-cffi \
+    ${PYTHON_PN}-cffi-native \
+    ${PYTHON_PN}-setuptools-rust-native \
+    ${PYTHON_PN}-six \
+"
+
+RDEPENDS:${PN} += " \
+    ${PYTHON_PN}-cffi \
+    ${PYTHON_PN}-idna \
+    ${PYTHON_PN}-asn1crypto \
+    ${PYTHON_PN}-setuptools \
+    ${PYTHON_PN}-six \
+"
+
+RDEPENDS:${PN}:class-target += " \
+    ${PYTHON_PN}-cffi \
+    ${PYTHON_PN}-idna \
+    ${PYTHON_PN}-numbers \
+    ${PYTHON_PN}-asn1crypto \
+    ${PYTHON_PN}-setuptools \
+    ${PYTHON_PN}-six \
+    ${PYTHON_PN}-threading \
+"
+
+RDEPENDS:${PN}-ptest += " \
+    ${PN} \
+    ${PYTHON_PN}-cryptography-vectors \
+    ${PYTHON_PN}-hypothesis \
+    ${PYTHON_PN}-iso8601 \
+    ${PYTHON_PN}-pretend \
+    ${PYTHON_PN}-pytest \
+    ${PYTHON_PN}-pytz \
+"
+
+inherit ptest
+
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/tests
+    cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+    install -d ${D}${PTEST_PATH}/tests/hazmat
+    cp -rf ${S}/tests/hazmat/* ${D}${PTEST_PATH}/tests/hazmat/
+}
+
+FILES:${PN}-dbg += " \
+    ${libdir}/${PYTHON_PN}2.7/site-packages/${SRCNAME}/hazmat/bindings/.debug \
+"
+
+BBCLASSEXTEND = "native nativesdk"
-- 
cgit 1.2.3-korg