From 37660c2e812996331d3c1a6e4d5dec3847ac4575 Mon Sep 17 00:00:00 2001
From: Joe MacDonald <joe@deserted.net>
Date: Mon, 7 Oct 2013 12:12:56 -0400
Subject: openflow: import and tweak
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Based on work by David Nyström (meta-virtualization) and Laszlo Papp
(meta-oe).

   - Import OpenFlow 1.0 from meta-virtualization and provide an updated
     version of the recipe for the head of tree in the OpenFlow git
     repository.

   - Minor tweak in both recipes for do_install_append() spacing.

   - Update 'libssl' PACKAGECONFIG flag in both to follow the 'openssl'
     convention used elsewhere in meta-oe.

   - Create common include file for both versioned and git recipes.

Signed-off-by: Joe MacDonald <joe@deserted.net>
---
 .../recipes-protocols/openflow/openflow.inc        | 35 ++++++++++++++++++++++
 .../recipes-protocols/openflow/openflow_1.0.bb     |  4 +++
 .../recipes-protocols/openflow/openflow_git.bb     |  4 +++
 3 files changed, 43 insertions(+)
 create mode 100644 meta-networking/recipes-protocols/openflow/openflow.inc
 create mode 100644 meta-networking/recipes-protocols/openflow/openflow_1.0.bb
 create mode 100644 meta-networking/recipes-protocols/openflow/openflow_git.bb

diff --git a/meta-networking/recipes-protocols/openflow/openflow.inc b/meta-networking/recipes-protocols/openflow/openflow.inc
new file mode 100644
index 0000000000..43af54ea59
--- /dev/null
+++ b/meta-networking/recipes-protocols/openflow/openflow.inc
@@ -0,0 +1,35 @@
+SUMMARY = "OpenFlow communications protocol"
+DESCRIPTION = "\
+Open standard that enables researchers to run experimental protocols in \
+contained networks.  OpenFlow is a communications interface between \
+control and forwarding planes of a software-defined networking architecture.\
+"
+HOMEPAGE = "http://www.openflow.org"
+
+SECTION = "networking"
+LICENSE = "GPLv2"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=e870c934e2c3d6ccf085fd7cf0a1e2e2"
+
+SRC_URI = "git://gitosis.stanford.edu/openflow.git;protocol=git"
+
+DEPENDS = "virtual/libc"
+
+EXTRA_OECONF += "KARCH=${TARGET_ARCH}"
+
+PACKAGECONFIG ??= "openssl"
+PACKAGECONFIG[openssl] = "--enable-ssl,--disable-ssl, openssl, libssl"
+
+S = "${WORKDIR}/git"
+
+inherit autotools
+
+do_configure() {
+    ./boot.sh
+    oe_runconf
+}
+
+do_install_append() {
+    # Remove /var/run as it is created on startup
+    rm -rf ${D}${localstatedir}/run
+}
diff --git a/meta-networking/recipes-protocols/openflow/openflow_1.0.bb b/meta-networking/recipes-protocols/openflow/openflow_1.0.bb
new file mode 100644
index 0000000000..a7e254dd85
--- /dev/null
+++ b/meta-networking/recipes-protocols/openflow/openflow_1.0.bb
@@ -0,0 +1,4 @@
+include ${BPN}.inc
+
+SRCREV = "5ccca75a69f99791659bcfbcf35353ab1921320a"
+PV = "1.0"
diff --git a/meta-networking/recipes-protocols/openflow/openflow_git.bb b/meta-networking/recipes-protocols/openflow/openflow_git.bb
new file mode 100644
index 0000000000..6403bfb220
--- /dev/null
+++ b/meta-networking/recipes-protocols/openflow/openflow_git.bb
@@ -0,0 +1,4 @@
+include ${BPN}.inc
+
+SRCREV = "c84f33f09d5dbcfc9b489f64cb30475bf36f653a"
+PV = "1.0+git${SRCPV}"
-- 
cgit 1.2.3-korg