4 files changed, 124 insertions, 0 deletions
diff --git a/meta-oe/recipes-support/pidgin/freeimage_3.17.0.bb b/meta-oe/recipes-support/pidgin/freeimage_3.17.0.bb
new file mode 100644
index 0000000000..e47dbe4aa8
--- /dev/null
+++ b/meta-oe/recipes-support/pidgin/freeimage_3.17.0.bb
@@ -0,0 +1,40 @@
+SUMMARY = "FreeImage tool used by WhatsApp Purple"
+SECTION = "webos/support"
+
+#Due to issues with CRLF line endings in LibWebP now using our own fork, so we don't need to patch in OE which caused issues. In future we migth be able to go back to upstream 3.18.0 release directly for example.
+SRC_URI = "git://github.com/webos-ports/FreeImage"
+
+SRCREV = "60b253f7cd9e82fb730cff7aa46b4eaa855443f1"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = " \
+    file://license-fi.txt;md5=7d2690b4d6d7dd53d69a773664bc4850 \
+    file://license-gplv2.txt;md5=0440c487be0c0200c36caf975ab31174 \
+    file://license-gplv3.txt;md5=e9661e0bea741d71a430b23475da519e \
+"
+
+S = "${WORKDIR}/git/"
+
+TARGET_CC_ARCH += "${LDFLAGS}"
+
+do_configure() {
+    sed -i -e /^CC/d \
+           -e /^CXX\ /d \
+           -e /^AR/d \
+           -e /^INCDIR\ /d \
+           -e /^INSTALLDIR\ /d \
+           -e s:'-o root -g root'::g \
+           -e /ldconfig/d \
+    ${S}/Makefile.gnu
+}
+
+do_install() {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    oe_runmake INSTALLDIR="${D}${libdir}" INCDIR="${D}${includedir}" install
+}
+
+INSANE_SKIP_${PN} = "already-stripped dev-so"
+
+FILES_${PN} += "${libdir}"
+FILES_SOLIBSDEV = "{libdir}/lib${BP}${SOLIBSDEV}"
diff --git a/meta-oe/recipes-support/pidgin/pidgin-sipe_1.21.1.bb b/meta-oe/recipes-support/pidgin/pidgin-sipe_1.21.1.bb
new file mode 100644
index 0000000000..48396549eb
--- /dev/null
+++ b/meta-oe/recipes-support/pidgin/pidgin-sipe_1.21.1.bb
@@ -0,0 +1,31 @@
+SUMMARY = "Protocol plugin for Office 365/Lync/OCS for Adium, Pidgin, Miranda and Telepathy IM Framework"
+SECTION = "webos/services"
+LICENSE = "GPLv2.0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+
+DEPENDS = "pidgin intltool-native"
+
+inherit pkgconfig
+inherit autotools
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/sipe/pidgin-sipe-${PV}.tar.xz"
+SRC_URI[md5sum] = "96ea396adb5c8a1bb1749d778892605c"
+SRC_URI[sha256sum] = "651af55d65cbdf5bdbee0366bd5151bec4152c910743aa432204d015893fe444"
+
+PACKAGECONFIG ??= "nss krb5"
+PACKAGECONFIG[nss] = "--enable-nss=yes,--enable-nss=no,nss"
+PACKAGECONFIG[openssl] = "--enable-openssl=yes,--enable-openssl=no,openssl"
+PACKAGECONFIG[krb5] = "--with-krb5=yes,--with-krb5=no,krb5"
+#PACKAGECONFIG[voice_and_video] = "--with-vv=yes,--with-vv=no,libnice gstreamer"
+PACKAGECONFIG[telepathy] = "--enable-telepathy=yes,--enable-telepathy=no,telepathy-glib gmime"
+#PACKAGECONFIG[gssapi_only] = "--enable-gssapi-only=yes,--enable-gssapi-only=no,krb5"
+PACKAGECONFIG[debug] = "--enable-debug=yes,--enable-debug=no,valgrind"
+
+FILES_${PN}-dev += " \
+    ${libdir}/purple-2/*.la \
+"
+
+FILES_${PN} += " \
+    ${libdir}/purple-2/libsipe.so \
+    ${datadir}/appdata \
+"
diff --git a/meta-oe/recipes-support/pidgin/purple-skypeweb_git.bb b/meta-oe/recipes-support/pidgin/purple-skypeweb_git.bb
new file mode 100644
index 0000000000..c4ed0358ab
--- /dev/null
+++ b/meta-oe/recipes-support/pidgin/purple-skypeweb_git.bb
@@ -0,0 +1,26 @@
+SUMMARY = "Skype protocol plug-in for libpurple"
+SECTION = "webos/services"
+LICENSE = "GPLv3"
+LIC_FILES_CHKSUM = "file://skypeweb/gpl3.txt;md5=d90260d32cef39f3c8d6c0f05d3adb8e"
+
+DEPENDS = "pidgin json-glib glib-2.0 zlib"
+
+inherit pkgconfig
+
+SRC_URI = "git://github.com/EionRobb/skype4pidgin;branch=master;protocol=git"
+SRCREV = "2b42d110708837d757b09ebc71e9e7053f259458"
+
+S = "${WORKDIR}/git"
+PV = "1.2.0+git${SRCPV}"
+
+do_compile() {
+    oe_runmake -C skypeweb;
+}
+
+do_install() {
+    oe_runmake -C skypeweb DESTDIR="${D}" install;
+}
+
+FILES_${PN} += " \
+    ${libdir} \
+"
diff --git a/meta-oe/recipes-support/pidgin/whatsapp-purple.bb b/meta-oe/recipes-support/pidgin/whatsapp-purple.bb
new file mode 100644
index 0000000000..99e1bb5a9b
--- /dev/null
+++ b/meta-oe/recipes-support/pidgin/whatsapp-purple.bb
@@ -0,0 +1,27 @@
+SUMMARY = "WhatsApp LibPurple Plugin"
+SECTION = "webos/services"
+LICENSE = "GPLv2.0+"
+LIC_FILES_CHKSUM = "file://debian/copyright;md5=6b066e36c765e83968e71478f54618f3"
+
+DEPENDS = "pidgin protobuf-native protobuf freeimage"
+
+SRCREV = "07ed931a3dd04c98a5f36e52129aa2cfe743a024"
+
+inherit pkgconfig
+
+SRC_URI = "git://github.com/davidgfnet/whatsapp-purple"
+PV = "0.9.0+git${SRCPV}"
+S = "${WORKDIR}/git"
+
+do_compile() {
+    oe_runmake CC="${CC}" CXX="${CXX}" EXTRA_INCLUDES="${TARGET_CFLAGS}" AR="${AR}";
+}
+
+do_install() {
+    oe_runmake DESTDIR="${D}" install;
+}
+
+FILES_${PN} += " \
+    ${libdir} \
+    ${datadir} \
+"