synergy: project has moved from synergy.googlecode.com

The synergy project on synergy.googlecode.com is defunct. The
sources cannot be downloaded from there anymore. The new project
home is synergy-project.org, but sources can only be downloaded
from ther with a login. The source code repo is on github.com/synergy.

New recipe to check out the code from GitHub. The code contains
zip archives for gmock and gtest, which need to be extracted before
do_configure. The license file has changed from COPYING to LICENSE. The
authors apparently added their copyright information before the GPLv2
license text. Hence, the md5sum is different.

Signed-off-by: Rudolf J Streif <rudolf.streif@gmail.com>

1 files changed, 34 insertions, 0 deletions

diff --git a/meta-oe/recipes-support/synergy/synergy_git.bb b/meta-oe/recipes-support/synergy/synergy_git.bb
new file mode 100644
index 0000000000..cb842c80b3
--- /dev/null
+++ b/meta-oe/recipes-support/synergy/synergy_git.bb
@@ -0,0 +1,34 @@
+SUMMARY = "Synergy - control multiple computers with one keyboard and mouse"
+HOMEPAGE = "http://synergy-project.org"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=0f366945b209c5523e39889f636af00a"
+LICENSE = "GPL-2.0"
+SECTION = "x11/utils"
+
+DEPENDS = "virtual/libx11 libxtst libxinerama"
+
+# depends on virtual/libx11
+REQUIRED_DISTRO_FEATURES = "x11"
+
+SRC_URI = "git://github.com/synergy/synergy.git;protocol=http"
+
+# Version 1.7.4-rc8
+SRCREV ?= "588fb4b805dd452556d05dbc03fe29ea5b4e43c0"
+PV = "1.7.3+1.7.4-rc8+${SRCPV}"
+
+S = "${WORKDIR}/git"
+
+inherit cmake distro_features_check
+
+do_unpack_extra() {
+    cd ${S}/ext
+    for file in *.zip; do
+        fname="${file##*/}"
+        unzip $file -d ${fname%.*}
+    done
+}
+addtask unpack_extra after do_unpack before do_patch
+
+do_install() {
+    install -d ${D}/usr/bin
+    install -m 0755 ${S}/bin/synergy* ${D}/usr/bin/
+}