summaryrefslogtreecommitdiffstats
path: root/meta/recipes-extended/psmisc/psmisc.inc
blob: 594a10cf2224de08905b5cf76b4d152c7a4bd6f9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
SUMMARY = "Utilities for managing processes on your system"
HOMEPAGE = "http://psmisc.sf.net/"
DESCRIPTION = "The psmisc package contains utilities for managing processes on your \
system: pstree, killall and fuser.  The pstree command displays a tree \
structure of all of the running processes on your system.  The killall \
command sends a specified signal (SIGTERM if nothing is specified) to \
processes identified by name.  The fuser command identifies the PIDs \
of processes that are using specified files or filesystems."
SECTION = "base"
DEPENDS = "ncurses virtual/libintl gettext-native"
LICENSE = "GPLv2"

SRC_URI = "${SOURCEFORGE_MIRROR}/psmisc/psmisc-${PV}.tar.gz"

S = "${WORKDIR}/psmisc-${PV}"

inherit autotools gettext

# Upstream has a custom autogen.sh which invokes po/update-potfiles as they 
# don't ship a po/POTFILES.in (which is silly).  Without that file gettext 
# doesn't believe po/ is a gettext directory and won't generate po/Makefile.
EXTRA_AUTORECONF_remove = "--exclude=autopoint"
do_configure_prepend() {
    ( cd ${S} && po/update-potfiles )
}


PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,"

ALLOW_EMPTY_${PN} = "1"

PACKAGES =+ "fuser fuser-doc killall killall-doc pstree pstree-doc"
PACKAGES += "psmisc-extras"

FILES_${PN} = ""
RDEPENDS_${PN} = "fuser killall pstree"

FILES_fuser = "${bindir}/fuser.${BPN}"
FILES_fuser-doc = "${mandir}/man1/fuser*"

FILES_killall = "${bindir}/killall.${BPN}"
FILES_killall-doc = "${mandir}/man1/killall*"

FILES_pstree = "${bindir}/pstree"
FILES_pstree-doc = "${mandir}/man1/pstree*"

FILES_psmisc-extras = "${bindir}"
FILES_psmisc-extras-doc = "${mandir}"

inherit update-alternatives

ALTERNATIVE_PRIORITY = "90"

ALTERNATIVE_killall = "killall"

ALTERNATIVE_fuser = "fuser"