summaryrefslogtreecommitdiffstats
path: root/meta/recipes-extended/pbzip2/pbzip2_1.1.13.bb
blob: 67fb2ef9c54bc30a4ac32f8ee328eba1ff6a446a (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
SUMMARY = "PBZIP2 is a parallel implementation of bzip2"
DESCRIPTION = "PBZIP2 is a parallel implementation of the bzip2 block-sorting \
file compressor that uses pthreads and achieves near-linear speedup on SMP \
machines. The output of this version is fully compatible with bzip2 v1.0.2 or \
newer (ie: anything compressed with pbzip2 can be decompressed with bzip2)."
HOMEPAGE = "http://compression.ca/pbzip2/"
SECTION = "console/utils"
LICENSE = "BSD"
LIC_FILES_CHKSUM = "file://COPYING;md5=4c4f2edec9679d5abef3514a816b54a4"

DEPENDS = "bzip2"
DEPENDS_append_class-native = " bzip2-replacement-native"

SRC_URI = "https://launchpad.net/${BPN}/1.1/${PV}/+download/${BP}.tar.gz"

SRC_URI[md5sum] = "4cb87da2dba05540afce162f34b3a9a6"
SRC_URI[sha256sum] = "8fd13eaaa266f7ee91f85c1ea97c86d9c9cc985969db9059cdebcb1e1b7bdbe6"

UPSTREAM_CHECK_URI = "http://compression.ca/pbzip2/"

do_configure[noexec] = "1"

EXTRA_OEMAKE = "CXX='${CXX} ${CXXFLAGS}' LDFLAGS='${LDFLAGS}'"

do_compile_prepend() {
    # Update timestamp to fix rebuild
    src_files="pbzip2.cpp BZ2StreamScanner.cpp ErrorContext.cpp"
    for f in $src_files; do
        if [ -f $f ]; then
            touch $f
        else
            bbwarn "Regular file $f not found"
        fi
    done
}

do_install() {
    install -d ${D}${bindir}
    install -m 0755 pbzip2 ${D}${bindir}/
}

BBCLASSEXTEND = "native"