aboutsummaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/meta/nativesdk-buildtools-perl-dummy.bb
blob: 2b96111600c24d0627d6ba11b52f1cc7b1c30873 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
SUMMARY = "Dummy package which ensures perl is excluded from buildtools"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"

inherit allarch

PR = "r2"

python() {
    # Put the package somewhere separate to ensure it's never used except
    # when we want it
    # (note that we have to do this in anonymous python here to avoid
    # allarch.bbclass disabling itself)
    d.setVar('PACKAGE_ARCH', 'buildtools-dummy-${SDKPKGSUFFIX}')
}

PERLPACKAGES = "nativesdk-perl \
                nativesdk-perl-module-file-path"

ALLOW_EMPTY_${PN} = "1"

python populate_packages_prepend() {
    d.appendVar(d.expand('RPROVIDES_${PN}'), '${PERLPACKAGES}')
    d.appendVar(d.expand('RCONFLICTS_${PN}'), '${PERLPACKAGES}')
    d.appendVar(d.expand('RREPLACES_${PN}'), '${PERLPACKAGES}')
}