aboutsummaryrefslogtreecommitdiffstats
path: root/meta/recipes-bsp/systemd-boot/systemd-boot.bb
blob: 0dc0fa3c067a3caf92ae8d74f842493eded9639c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
require recipes-core/systemd/systemd.inc

DEPENDS = "intltool-native libcap util-linux gnu-efi"

inherit autotools pkgconfig gettext
inherit deploy

EXTRA_OECONF = " --enable-gnuefi \
                 --with-efi-includedir=${STAGING_INCDIR} \
                 --with-efi-ldsdir=${STAGING_LIBDIR} \
                 --with-efi-libdir=${STAGING_LIBDIR} \
                 --disable-manpages \
               "

# Imported from gummiboot recipe
TUNE_CCARGS_remove = "-mfpmath=sse"
COMPATIBLE_HOST = "(x86_64.*|i.86.*)-linux"

do_compile() {
	SYSTEMD_BOOT_EFI_ARCH="ia32"
	if [ "${TARGET_ARCH}" = "x86_64" ]; then
		SYSTEMD_BOOT_EFI_ARCH="x64"
	fi

	oe_runmake systemd-boot${SYSTEMD_BOOT_EFI_ARCH}.efi
}

do_install() {
	# Bypass systemd installation with a NOP
	:
}

do_deploy () {
	install ${B}/systemd-boot*.efi ${DEPLOYDIR}
}
addtask deploy before do_build after do_compile