aboutsummaryrefslogtreecommitdiffstats
path: root/meta/conf/multilib.conf
blob: ce97d5d0144cc166aaeae9821506448a899a8e92 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
baselib = "${@d.getVar('BASE_LIB_tune-' + (d.getVar('DEFAULTTUNE') or 'INVALID'), True) or d.getVar('BASELIB')}"

MULTILIB_VARIANTS = "${@extend_variants(d,'MULTILIBS','multilib')}"
MULTILIB_SAVE_VARNAME = "DEFAULTTUNE TARGET_ARCH TARGET_SYS TARGET_VENDOR"

MULTILIBS ??= "multilib:lib32"

STAGING_DIR_HOST = "${STAGING_DIR}/${MLPREFIX}${MACHINE}"
STAGING_DIR_TARGET = "${STAGING_DIR}/${MLPREFIX}${MACHINE}"
PKGDATA_DIR = "${STAGING_DIR}/${MACHINE}/pkgdata"

INHERIT += "multilib_global"

BBCLASSEXTEND_append = " ${MULTILIBS}"

MULTILIB_GLOBAL_VARIANTS ?= "lib32 lib64 libx32"

OPKG_ARGS_append = " --force-maintainer --force-overwrite"

# When multilib is enabled, allarch recipes will be installed into the MACHINE
# sysroot, not MLPREFIXMACHINE.  This means that anything using pkg-config to
# find an allarch pkgconfig file will fail as the PKG_CONFIG_PATH only looks
# inside the multilib sysroot.  Fix this by explicitly adding the MACHINE's
# architecture-independent pkgconfig location to PKG_CONFIG_PATH.
PKG_CONFIG_PATH .= ":${STAGING_DIR}/${MACHINE}${datadir}/pkgconfig"
PKG_CONFIG_PATH[vardepsexclude] = "MACHINE datadir STAGING_DIR"
PKG_CONFIG_PATH[vardepvalueexclude] = ":${STAGING_DIR}/${MACHINE}${datadir}/pkgconfig"