From 55a2d8619b0a3e5606076808d306cd78cf3edf41 Mon Sep 17 00:00:00 2001
From: Hong Liu <hongl.fnst@cn.fujitsu.com>
Date: Wed, 17 Oct 2018 08:40:16 +0800
Subject: harfbuzz: upgrade 1.8.8->1.9.0

Upgrade harfbuzz from 1.8.8 to 1.9.0.

Signed-off-by: Hong Liu <hongl.fnst@cn.fujitsu.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 meta/recipes-graphics/harfbuzz/harfbuzz_1.9.0.bb | 46 ++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 meta/recipes-graphics/harfbuzz/harfbuzz_1.9.0.bb

(limited to 'meta/recipes-graphics/harfbuzz/harfbuzz_1.9.0.bb')

diff --git a/meta/recipes-graphics/harfbuzz/harfbuzz_1.9.0.bb b/meta/recipes-graphics/harfbuzz/harfbuzz_1.9.0.bb
new file mode 100644
index 0000000000..0b27634830
--- /dev/null
+++ b/meta/recipes-graphics/harfbuzz/harfbuzz_1.9.0.bb
@@ -0,0 +1,46 @@
+SUMMARY = "Text shaping library"
+DESCRIPTION = "HarfBuzz is an OpenType text shaping engine."
+HOMEPAGE = "http://www.freedesktop.org/wiki/Software/HarfBuzz"
+BUGTRACKER = "https://bugs.freedesktop.org/enter_bug.cgi?product=HarfBuzz"
+SECTION = "libs"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=e021dd6dda6ff1e6b1044002fc662b9b \
+                    file://src/hb-ucdn/COPYING;md5=994ba0f1295f15b4bda4999a5bbeddef \
+"
+
+DEPENDS = "glib-2.0 cairo fontconfig freetype"
+
+SRC_URI = "http://www.freedesktop.org/software/harfbuzz/release/${BP}.tar.bz2"
+SRC_URI[md5sum] = "263a3f1cb014e3ad2e4123c238a9bfc5"
+SRC_URI[sha256sum] = "11eca62bf0ac549b8d6be55f4e130946399939cdfe7a562fdaee711190248b00"
+
+inherit autotools pkgconfig lib_package gtk-doc
+
+PACKAGECONFIG ??= "icu"
+PACKAGECONFIG[icu] = "--with-icu,--without-icu,icu"
+
+EXTRA_OECONF = " \
+    --with-cairo \
+    --with-fontconfig \
+    --with-freetype \
+    --with-glib \
+    --without-graphite2 \
+"
+
+do_configure_prepend() {
+    # This is ancient and can get used instead of the patched one we ship,
+    # so delete it. In 1.8.9 this should be removed upstream.
+    rm -f ${S}/m4/pkg.m4
+}
+
+PACKAGES =+ "${PN}-icu ${PN}-icu-dev"
+
+LEAD_SONAME = "libharfbuzz.so"
+
+FILES_${PN}-icu = "${libdir}/libharfbuzz-icu.so.*"
+FILES_${PN}-icu-dev = "${libdir}/libharfbuzz-icu.la \
+                       ${libdir}/libharfbuzz-icu.so \
+                       ${libdir}/pkgconfig/harfbuzz-icu.pc \
+"
+
+BBCLASSEXTEND = "native"
-- 
cgit 1.2.3-korg