1 files changed, 45 insertions, 0 deletions
diff --git a/meta/recipes-webos/luna-init/luna-init.bb b/meta/recipes-webos/luna-init/luna-init.bb
new file mode 100644
index 0000000000..5be37da91b
--- /dev/null
+++ b/meta/recipes-webos/luna-init/luna-init.bb
@@ -0,0 +1,45 @@
+# Copyright (c) 2012-2018 LG Electronics, Inc.
+
+SUMMARY = "Initialization, setup, and font files used by luna-sysmgr and luna-sysservice"
+AUTHOR = "Alekseyev Oleksandr <alekseyev.oleksandr@lge.com>"
+SECTION = "webos/base"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+
+DEPENDS = "tzdata python-tz-native"
+
+WEBOS_VERSION = "2.0.1-1_701ec4b373b776fba829c882b05ae19de9a476ed"
+PR = "r14"
+
+#inherit webos_component TODO
+inherit webos_arch_indep
+inherit webos_public_repo
+inherit webos_enhanced_submissions
+inherit webos_cmake
+inherit pythonnative
+
+SRC_URI = "${WEBOSOSE_GIT_REPO_COMPLETE}"
+S = "${WORKDIR}/git"
+
+do_install_append() {
+    # Expand fonts tarball
+    if [ -e ${S}/files/conf/fonts/fonts.tgz ]; then
+        install -d ${D}${datadir}/fonts
+        tar xvzf ${S}/files/conf/fonts/fonts.tgz --directory=${D}${datadir}/fonts
+    fi
+    install -d ${D}${webos_sysconfdir}
+    install -v -m 644 ${S}/files/conf/locale.txt ${D}${webos_sysconfdir}
+}
+
+do_install_append_webos() {
+    install -v -m 644 ${S}/files/conf/apollo/defaultPreferences.txt ${D}${webos_sysconfdir}
+}
+
+PACKAGES =+ "${PN}-fonts"
+FILES_${PN} += "${webos_prefix} ${webos_sysconfdir}"
+FILES_${PN}-fonts += "${datadir}/fonts/"
+
+# until pseudo is completely fixed
+# PLAT-48507 pseudo: random package_qa failures
+# This issue seems to be triggered only in luna-init-fonts packages
+#INSANE_SKIP_${PN}-fonts += "host-user-contaminated"