aboutsummaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/cmake/cmake_3.7.0.bb
diff options
context:
space:
mode:
authorAlexander Kanavin <alexander.kanavin@linux.intel.com>2016-11-28 15:34:17 +0200
committerRichard Purdie <richard.purdie@linuxfoundation.org>2016-11-30 15:47:16 +0000
commitf9abf70ef9e55be4bdbf90836a8ba083210f82ad (patch)
treea6d430f0a5e25cba90035f5fffaae24d44b81fe7 /meta/recipes-devtools/cmake/cmake_3.7.0.bb
parent1008d711b57d82313e53f767fd6fae93e10418ea (diff)
downloadopenembedded-core-contrib-f9abf70ef9e55be4bdbf90836a8ba083210f82ad.tar.gz
openembedded-core-contrib-f9abf70ef9e55be4bdbf90836a8ba083210f82ad.tar.bz2
openembedded-core-contrib-f9abf70ef9e55be4bdbf90836a8ba083210f82ad.zip
cmake: update to 3.7.0
License is still 3-clause BSD. Signed-off-by: Alexander Kanavin <alexander.kanavin@linux.intel.com> Signed-off-by: Ross Burton <ross.burton@intel.com>
Diffstat (limited to 'meta/recipes-devtools/cmake/cmake_3.7.0.bb')
-rw-r--r--meta/recipes-devtools/cmake/cmake_3.7.0.bb49
1 files changed, 49 insertions, 0 deletions
diff --git a/meta/recipes-devtools/cmake/cmake_3.7.0.bb b/meta/recipes-devtools/cmake/cmake_3.7.0.bb
new file mode 100644
index 0000000000..58c6615680
--- /dev/null
+++ b/meta/recipes-devtools/cmake/cmake_3.7.0.bb
@@ -0,0 +1,49 @@
+require cmake.inc
+
+inherit cmake
+
+DEPENDS += "curl expat zlib libarchive xz ncurses bzip2"
+
+SRC_URI_append_class-nativesdk = " \
+ file://OEToolchainConfig.cmake \
+ file://environment.d-cmake.sh"
+
+# Strip ${prefix} from ${docdir}, set result into docdir_stripped
+python () {
+ prefix=d.getVar("prefix", True)
+ docdir=d.getVar("docdir", True)
+
+ if not docdir.startswith(prefix):
+ bb.fatal('docdir must contain prefix as its prefix')
+
+ docdir_stripped = docdir[len(prefix):]
+ if len(docdir_stripped) > 0 and docdir_stripped[0] == '/':
+ docdir_stripped = docdir_stripped[1:]
+
+ d.setVar("docdir_stripped", docdir_stripped)
+}
+
+EXTRA_OECMAKE=" \
+ -DCMAKE_DOC_DIR=${docdir_stripped}/cmake-${CMAKE_MAJOR_VERSION} \
+ -DCMAKE_USE_SYSTEM_LIBRARIES=1 \
+ -DCMAKE_USE_SYSTEM_LIBRARY_JSONCPP=0 \
+ -DCMAKE_USE_SYSTEM_LIBRARY_LIBUV=0 \
+ -DKWSYS_CHAR_IS_SIGNED=1 \
+ -DBUILD_CursesDialog=0 \
+ ${@bb.utils.contains('DISTRO_FEATURES', 'largefile', '-DKWSYS_LFS_WORKS=1', '-DKWSYS_LFS_DISABLE=1', d)} \
+"
+
+do_install_append_class-nativesdk() {
+ mkdir -p ${D}${datadir}/cmake
+ install -m 644 ${WORKDIR}/OEToolchainConfig.cmake ${D}${datadir}/cmake/
+
+ mkdir -p ${D}${SDKPATHNATIVE}/environment-setup.d
+ install -m 644 ${WORKDIR}/environment.d-cmake.sh ${D}${SDKPATHNATIVE}/environment-setup.d/cmake.sh
+}
+
+FILES_${PN}_append_class-nativesdk = " ${SDKPATHNATIVE}"
+
+FILES_${PN} += "${datadir}/cmake-${CMAKE_MAJOR_VERSION}"
+FILES_${PN}-doc += "${docdir}/cmake-${CMAKE_MAJOR_VERSION}"
+
+BBCLASSEXTEND = "nativesdk"