aboutsummaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/glib-2.0/glib-2.0_2.36.3.bb
diff options
context:
space:
mode:
authorCristian Iorga <cristian.iorga@intel.com>2013-07-04 15:08:56 +0000
committerSaul Wold <sgw@linux.intel.com>2013-07-09 07:56:09 -0700
commitb46b7ccc7be5c880f79053535dc1c10ba5fbd5f4 (patch)
tree31bbb3d9e2b59b8ec682b9ede65c96d7df491e31 /meta/recipes-core/glib-2.0/glib-2.0_2.36.3.bb
parent6ac06a65ce52d4c123da53f115c84cb0a98bc18f (diff)
downloadopenembedded-core-contrib-b46b7ccc7be5c880f79053535dc1c10ba5fbd5f4.tar.gz
glib-2.0: upgrade to 2.36.3
Signed-off-by: Cristian Iorga <cristian.iorga@intel.com> Signed-off-by: Saul Wold <sgw@linux.intel.com>
Diffstat (limited to 'meta/recipes-core/glib-2.0/glib-2.0_2.36.3.bb')
-rw-r--r--meta/recipes-core/glib-2.0/glib-2.0_2.36.3.bb63
1 files changed, 63 insertions, 0 deletions
diff --git a/meta/recipes-core/glib-2.0/glib-2.0_2.36.3.bb b/meta/recipes-core/glib-2.0/glib-2.0_2.36.3.bb
new file mode 100644
index 0000000000..463dc0d501
--- /dev/null
+++ b/meta/recipes-core/glib-2.0/glib-2.0_2.36.3.bb
@@ -0,0 +1,63 @@
+require glib.inc
+
+PE = "1"
+
+DEPENDS += "libffi zlib"
+DEPENDS_class-native += "libffi-native"
+DEPENDS_class-nativesdk += "nativesdk-libffi nativesdk-zlib ${BPN}-native"
+
+SHRT_VER = "${@d.getVar('PV',1).split('.')[0]}.${@d.getVar('PV',1).split('.')[1]}"
+
+SRC_URI = "${GNOME_MIRROR}/glib/${SHRT_VER}/glib-${PV}.tar.xz \
+ file://configure-libtool.patch \
+ file://glib-2.0_fix_for_x32.patch \
+ file://fix-conflicting-rand.patch \
+ file://Makefile-ptest.patch \
+ file://run-ptest \
+ "
+
+SRC_URI_append_class-native = " file://glib-gettextize-dir.patch"
+
+SRC_URI[md5sum] = "89180c7354b0acd3efb0a36ac05ca39c"
+SRC_URI[sha256sum] = "5ec433bf6ce02e4c436619c3d0b9cecdd1898469398a636bad27c1f5804c761e"
+
+BBCLASSEXTEND = "native nativesdk"
+
+RDEPENDS_${PN}-ptest += "\
+ tzdata \
+ tzdata-americas \
+ tzdata-asia \
+ tzdata-europe \
+ tzdata-posix \
+ python-pygobject \
+ python-dbus \
+ "
+
+RDEPENDS_${PN}-ptest_append_libc-glibc = "\
+ eglibc-gconv-utf-16 \
+ eglibc-charmap-utf-8 \
+ eglibc-gconv-cp1255 \
+ eglibc-charmap-cp1255 \
+ eglibc-gconv-utf-32 \
+ eglibc-gconv-utf-7 \
+ eglibc-charmap-invariant \
+ eglibc-localedata-translit-cjk-variants \
+ "
+
+do_configure_prepend() {
+ sed -i -e '1s,#!.*,#!${USRBINPATH}/env python,' ${S}/gio/gdbus-2.0/codegen/gdbus-codegen.in
+}
+
+do_install_append() {
+ # remove some unpackaged files
+ rm -f ${D}${datadir}/glib-2.0/codegen/*.pyc
+ rm -f ${D}${datadir}/glib-2.0/codegen/*.pyo
+ # and empty dirs
+ rm -rf ${D}${libdir}/gio
+
+ # Some distros have both /bin/perl and /usr/bin/perl, but we set perl location
+ # for target as /usr/bin/perl, so fix it to /usr/bin/perl.
+ if [ -f ${D}${bindir}/glib-mkenums ]; then
+ sed -i -e '1s,#!.*perl,#! ${USRBINPATH}/env perl,' ${D}${bindir}/glib-mkenums
+ fi
+}