aboutsummaryrefslogtreecommitdiffstats
path: root/recipes-qtopia/poboxserver/poboxserver_1.2.5.bb
blob: 02aa6d2c548623670ebf13d369b38fdd7d29cf09 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
DESCRIPTION = "OpenPOBox is an open source implementation of a 'Predictive Operation Based On eXample'"
SECTION = "inputmethods"
LICENSE = "GPL"
DEPENDS = "perl-native ruby-native nkf-native"
PR = "r8"

SRC_URI = "${SOURCEFORGE_MIRROR}/gakusei/pobox-${PV}.tar.bz2;name=archive \
           http://www.vanille.de/mirror/pbserver-${PV}.tar.gz;name=pbserver \
           file://OpenPOBox-1.25.diff \
           file://remove-local-includes.patch \
           file://unicode.patch;patchdir=${WORKDIR}/pbserver \
           file://pbserver.sh"

S = "${WORKDIR}/OpenPOBox"

inherit autotools update-rc.d palmtop-defs

INITSCRIPT_NAME = "pbserver"
INITSCRIPT_PARAMS = "start 99 5 . stop 01 0 ."

EXTRA_OECONF = "--enable-lookup"
PARALLEL_MAKE = ""

do_compile() {
	oe_runmake
	cp ${S}/dict/data/fugodic ${WORKDIR}/pbserver/fugodic.txt
	oe_runmake -C ${WORKDIR}/pbserver dic
	#patch -p1
}

do_install() {
	install -d ${D}${palmtopdir}/pobox/
	install -m 0755 ${S}/server/pbserver ${D}${palmtopdir}/pobox/
	install -m 0644 ${WORKDIR}/pbserver/staticdic ${D}${palmtopdir}/pobox/
	install -m 0644 ${WORKDIR}/pbserver/learndic ${D}${palmtopdir}/pobox/
	install -d ${D}${sysconfdir}/init.d/
	install -m 0755 ${WORKDIR}/pbserver.sh ${D}${sysconfdir}/init.d/pbserver
	sed -i -e 's,@palmtopdir@,${palmtopdir},g' ${D}${sysconfdir}/init.d/pbserver
}

FILES_${PN}-dbg += "${palmtopdir}/pobox/.debug"
FILES_${PN} += "${palmtopdir}/pobox/*"

SRC_URI[archive.md5sum] = "d1c988c2ac06d3111f80d59d30bb8bbb"
SRC_URI[archive.sha256sum] = "73bbc333d2a51d0e1cd73030012f2727ac26f5b1d41333994b01a47486fc16db"
SRC_URI[pbserver.md5sum] = "7afe4cb20d36b7d00002a522cbe724a8"
SRC_URI[pbserver.sha256sum] = "c64986ede63deda10a4b0aa5fd3fda1ae7fcd28d91ecc149fceec4ccffd9c620"